formula for vlookup 2 cells

[beancurdjelly2003]

How can I set the formula for vlookup more than 1 cells?

e.g.
Sheet 1> columns A and B > vlookup to another Sheet 2 columns C

I need to get back the result for columns C

 

[Matt Richardson]

How can I set the formula for vlookup more than 1 cells?

e.g.
Sheet 1> columns A and B > vlookup to another Sheet 2 columns C

I need to get back the result for columns C

Can you elaborate on this a little more? Can you give an example of
your data in columns A, B and C and how they might relate to each
other so I can get a better picture of what needs to be done?

Kind regards,
Matt Richardson
http://teachr.blogspot.com

 

[Nigel]

Use concatenate to bring the two values together e.g you have to be careful
depending on what type of values column A and B are......

=VLOOKUP(CONCATENATE(A1,B1),X1:Z100,2,FALSE)

 

[Dave Peterson]

Saved from a previous post:

If you want exact matches for just two columns (and return a value from a
third), you could use:

=index(othersheet!$c$1:$c$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100),0))

(all in one cell)

This is an array formula. Hit ctrl-shift-enter instead of enter. If you do it
correctly, excel will wrap curly brackets {} around your formula. (don't type
them yourself.)

Adjust the range to match--but you can only use the whole column in xl2007.

This returns the value in othersheet column C when column A and B (of
othersheet) match A2 and B2 of the sheet with the formula.

And you can add more conditions by just adding more stuff to that product
portion of the formula:

=index(othersheet!$d$1:$d$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100)
*(c2=othersheet!$c$1:$c$100),0))