find number position in excel text cell

[Guest]

I have a spreadsheet with a column of amatuer radio call signs that consist
of a numerical digit in text. The text string can vary in length and the
numbers position can also vary within the text. I would like to find the
position of the number in the text. Any help is appreciated.
Thanks
Don

 

[Guest]

Try something like this:

For a value in A1
B1: =MIN(SEARCH({0,1,2,3,4,5,6,7,8,9},A1&"0123456789"))

If A1: wavc1asd
the formula returns 5 (the number is in the 5th position)

Does that help?

***********
Regards,
Ron

XL2002, WinXP-Pro

 

[Guest]

Ron,
That does find the position number of the number but when I try to use it
in my function it returns a #VALUE error . I saved the position number in
column P and have tryed to convert text to number just in case that was the
problem. Here is the code I am trying to use:
=RIGHT(CALL,(LEN(CALL)-FIND(P2,CALL,1)))

Again thanks for the help and the quick response.

Don

 

[Guest]

If you're trying to pull from the 1st number to the end of the string in the
cell named CALL, try this:

=MID(CALL,MIN(SEARCH({0,1,2,3,4,5,6,7,8,9},A1&"0123456789")),255)

Does that help?

***********
Regards,
Ron

XL2002, WinXP-Pro

 

[Guest]

If you only want the letters after the 1st digit in the string, then how
about this:

=MID(CALL,MIN(SEARCH({0,1,2,3,4,5,6,7,8,9},A1&"0123456789"))+1,255)

Am I on the right track here?

***********
Regards,
Ron

XL2002, WinXP-Pro

 

[Guest]

Ron,
I was able to make it work thanks to your help. Here is what I came up
with to make it work:

=RIGHT(CALL,(LEN(CALL)-((MIN(SEARCH({0,1,2,3,4,5,6,7,8,9},C4&"0123456789"))))))

This gives me exatly what I want.
Thank you very much.

Don