FillColBlanks - two columns?

[J.W. Aldridge]

Need to fix this code to run on 2 columns.... (column A & B).

Any ideas?

Sub FillColBlanksA()
Dim wks As Worksheet
Dim Rng As Range
Dim lastrow As Long
Dim col As Long


Set wks = ActiveSheet
With wks
col = .Range("A1").Column


Set Rng = .UsedRange
lastrow = .Cells.SpecialCells(xlCellTypeLastCell).Row
Set Rng = Nothing
On Error Resume Next
Set Rng = .Range(.Cells(2, col), .Cells(lastrow, col)) _
.Cells.SpecialCells(xlCellTypeBlanks)
On Error GoTo 0


If Rng Is Nothing Then
MsgBox "No blanks found"
Exit Sub
Else
Rng.FormulaR1C1 = "=R[-1]C"
End If


With .Cells(1, col).EntireColumn
.Value = .Value
End With


End With


End Sub

 

[Guest]

Sub FillColBlanksA()
Dim wks As Worksheet
Dim Rng As Range
Dim lastrow As Long
Dim col As Long


Set wks = ActiveSheet
With wks
col = .Range("A1").Column


lastrow = .Cells.SpecialCells(xlCellTypeLastCell).Row
Set Rng = Nothing
On Error Resume Next
' added code to the below command
Set Rng = .Range(.Cells(2, col), .Cells(lastrow, col)) _
.Resize(,2).SpecialCells(xlCellTypeBlanks)
On Error GoTo 0


If Rng Is Nothing Then
MsgBox "No blanks found"
Exit Sub
Else
Rng.FormulaR1C1 = "=R[-1]C"
End If

' added code below
With .Cells(1, col).Resize(,2).EntireColumn
.Value = .Value
End With


End With


End Sub

 

[J.W. Aldridge]

THANX A MILLION!!!!!