Expanded Vlookup

[Brad]

Okay, I need a way to compare two cells in one workbook to two columns in
another workbook. When I find those two cells that match exactly then I need
to return a value in another column.

I figure it is some kind of an expanded Vlookup. This is what I've come up
with so far, but I can't figure out how to make it work.

=VLOOKUP(A1:B2,'[workbook]worksheet1'!$A$2:$E$1000,4,FALSE)

 

[Pete_UK]

In your second workbook (the one with the table), can you insert a new
column C and join the two items of data together like this:

=A2&B2

assuming the lookup values are in columns A and B ?

If so, then you could have a formula like:

=VLOOKUP(A1&B1,'path[filename.xls]sheet1'!$C$2:$F$1000,3,0)

Hope this helps.

Pete

 

[Dave Peterson]

I'm gonna guess you meant two cells (a1:b1), not four cells (a1:b2)...

Saved from a previous post:

If you want exact matches for just two columns (and return a value from a
third), you could use:

=index(othersheet!$c$1:$c$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100),0))

(all in one cell)

This is an array formula. Hit ctrl-shift-enter instead of enter. If you do it
correctly, excel will wrap curly brackets {} around your formula. (don't type
them yourself.)

Adjust the range to match--but you can only use the whole column in xl2007.

This returns the value in othersheet column C when column A and B (of
othersheet) match A2 and B2 of the sheet with the formula.

And you can add more conditions by just adding more stuff to that product
portion of the formula:

=index(othersheet!$d$1:$d$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100)
*(c2=othersheet!$c$1:$c$100),0))

Okay, I need a way to compare two cells in one workbook to two columns in
another workbook. When I find those two cells that match exactly then I need
to return a value in another column.

I figure it is some kind of an expanded Vlookup. This is what I've come up
with so far, but I can't figure out how to make it work.

=VLOOKUP(A1:B2,'[workbook]worksheet1'!$A$2:$E$1000,4,FALSE)