Excel VBA - Exporting values to a txt file

[schumacker]

Hi everyone!!

i wanna do a macro for an excel file, and i want it to do the
following:

1 - Get the values one by one from a column
2 - Put the values in a txt file.

Example:

Excel file:

A B
1 hello
2 world
3 welcome
4 everybody
5
6
7


Text file:

hello
world
welcome
everybody

It seems to me that this must be very very easy to do, but i am very
very new in the Visual Basic world, and i dont have any idea of the
names of the methods.

If anyone can help me... thanks

Schumacker

 

[Harald Staff]

Hi Schumacker

See if any of this is of use:

Sub Export2Textfile()
Dim Textfile As Variant
Dim LastRow As Long
Dim XportArea As Range
Dim Cel As Range
Dim iFnum As Integer
'Select a textfile to save to
Textfile = Application.GetSaveAsFilename( _
InitialFilename:="text.txt", _
FileFilter:="Text files, *.txt)", _
Title:="Save textfile as:")
If Textfile = False Then Exit Sub
On Error Resume Next
'Select the cells to export:
Set XportArea = Application.InputBox( _
"Select the cells to export:", _
"Use your mouse:", Selection.Address, Type:=8)
If XportArea Is Nothing Then Exit Sub
'open / create the textfile
iFnum = FreeFile
Open CStr(Textfile) For Output As iFnum
'loop cells
For Each Cel In XportArea
'write to textfile
Print #iFnum, Cel.Text
Next
Close #iFnum
End Sub

 

[papou]

Hello Schumaker

Sub EcrireFichierTexte()
Dim Montexte As String
'adapt path and textfile name
Open "D:\Mes Documents\TestEcriture.txt" For Output As #1
'adpat column
For i = 1 To Range("A65536").End(xlUp).Row
Montexte = Cells(i, 1)
Print #1, Montexte
Next i
Close #1
End Sub

HTH
Regards
Pascal