Empty cell in vlookup

[confused]

hi, is there a way to have a vlookup see an empty cell and rather than
filling it in with a 0 it could leave it blank? here's my vlookup formula

=IF(A21="","",VLOOKUP(A21,'PN Source Code'!$A$1:$H$25,8,FALSE))

Thank you in advance for your help

 

[Eva]

=IF(A21="","",if(VLOOKUP(A21,'PN Source
Code'!$A$1:$H$25,8,FALSE)="","",VLOOKUP(A21,'PN Source
Code'!$A$1:$H$25,8,FALSE)))

--
Please click "yes" if this post helped you!

Greatly appreciated

Eva

 

[confused]

Thanks you Eva, this was very helpful

=IF(A21="","",if(VLOOKUP(A21,'PN Source
Code'!$A$1:$H$25,8,FALSE)="","",VLOOKUP(A21,'PN Source
Code'!$A$1:$H$25,8,FALSE)))

--
Please click "yes" if this post helped you!

Greatly appreciated

Eva

 

[Eva]

you are very welcome.
--
Please click "yes" if this post helped you!

Greatly appreciated

Eva

 

[Art]

I was excited to see this post as I was trying to figure out the same thing!

MY CODE (Excel 2007)
=IF(ISERROR(VLOOKUP(K6,Developers!$D$5:$R$143,6,0)),"",VLOOKUP(K6,Developers!$D$5:$R$143,6,0))

USING YOUR IDEA
=IF(K6="","",if(VLOOKUP(K6,Developers!$D$5:$R$143,6,FALSE)="","",VLOOKUP(K6,Developers!$D$5:$R$143,6,FALSE)))

However, I get a #N/A error now when before it correctly filled the cell
with the information.

In some instances, there is no data in the other sheet, so it displays 0. I,
like "confused", want to replace the 0 with a blank.

Thanks!

 

[T. Valko]

What type of data does your lookup formula return, is it text or numeric or
can it be either?

 

[Art]

Text.

The user selects a course developer from a drop-down box on the Development!
sheet in Column K (which is populated from data in the Courses! sheet). After
making a selection, the developer's e-mail addres, for example, appears in
Column L. The spreadsheet gets this information from the Developers! sheet.

With the formula I used before, it works correctly. It just puts 0 in the
cell if there is no e-mail address currently in the Developers! sheet.

I just want to replace the 0 with a blank, until an e-mail address is
entered in the Developers! sheet.

Thanks!

 

[T. Valko]

Try this...

=IF(COUNTIF(Developers!$D$5:$D$143,K6),T(VLOOKUP(K6,Developers!$D$5:$R$143,6,0)),"")

 

[Art]

Perfect. Thank you VERY much!!!

Try this...

=IF(COUNTIF(Developers!$D$5:$D$143,K6),T(VLOOKUP(K6,Developers!$D$5:$R$143,6,0)),"")

--
Biff
Microsoft Excel MVP





.

 

[T. Valko]

You're welcome. Thanks for the feedback!