Easy Worksheet Function help

[Office_Novice]

Where did i go wrong?

=IF(F4='> 100',"1",)OR(F4='76 - 100',"2",)OR(F4='51 - 75',"3",)OR(F4='26 -
50',"4",)OR(F4='< 25',"5")

Basically…

If F4 is equal ‘> 100’ then display a 1 or, if F4 is equal to ’76 – 100’
then display a 2 or, if F4 is equal to ’51 – 75’ then display a 3

 

[Mike H]

Hi,

Because you don't say what you want if F4 <51 this produces unspecified

=IF(F4>100,1,IF(F4>=76,2,IF(F4>=51,3,"Unspecified")))

Mike

 

[Gary''s Student]

=(F4="> 100")*1+(F4="76 - 100")*2+(F4="51 - 75")*3+(F4="26 - 50")*4+(F4="<
25")*5

 

[Ron Coderre]

Try this:

=SUM((F4={"> 100","76 - 100","51 - 75","26 - 50","< 25"})*{1,2,3,4,5})


Does that help?
Post back if you have more questions.
--------------------------

Regards,

Ron
Microsoft MVP (Excel)
(XL2003, Win XP)

 

[Rick Rothstein \(MVP - VB\)]

Assuming your entries in the cell are text strings as shown (for example,
the cell contains the text "51 - 75", without the quote marks and without
the apostrophes that your examples show, and not an actual value between 51
and 75), this formula will return the results you want...

=MATCH(LEFT(A1),{">","7","5","2","<"},0)

Rick

 

[Rick Rothstein \(MVP - VB\)]

By the way... in your listing of ranges, the value 25 is not covered in any
of them. Perhaps the last range should be '<=25' (note the equal sign)
rather then '<25'.

Rick