Each rows last cell text value could be in any columns.

[Guest]

Is it possible using a formula, to return the last text value in a row where
the last cell text value could be in any column from C to Z.
Below is a layout example;

Row A B C D................Z result
1. ?? ?? true true
2. ?? ?? ?? true true
3. ?? ?? ?? ?? false false

TIA
--
Thank you

Regards
Aussie Bob C.
Using Windows XP Home + Office 2003 Pro SP2

 

[Biff]

Hi!

Are your trues and falses TEXT values and not LOGICAL values?

To find the last TEXT entry in the range C1:Z1:

=LOOKUP(REPT("z",255),C1:Z1)

Biff

 

[Guest]

Hi Biff

They are logical values.
I could copy and paste values in place before entering your formula if that
would help.

--
Thank you

Regards
Aussie Bob C.
Using Windows XP Home + Office 2003 Pro SP2

 

[Biff]

Try this for LOGICALS:

Array entered using the key combo of CTRL,SHIFT,ENTER:

=INDEX(C1:Z1,MAX((C1:Z1<>"")*(COLUMN(C1:Z1)-COLUMN(C1)+1)))

Biff

 

[Aladin Akyurek]

Two options...

1]

=CHOOSE(LOOKUP(9.99999999999999E+307,LOOKUP(A1:Z1,{0,FALSE,TRUE},{"",0,1}))+1,FALSE,TRUE)

2]

=LOOKUP(2,1/ISLOGICAL(A1:Z1),A1:Z1)

 

[Guest]

Thank you Biff

Works just great!

--
Thank you

Regards
Aussie Bob C.
Using Windows XP Home + Office 2003 Pro SP2

 

[Biff]

You're welcome!

Just a note: that formula will return the last value in the range be it
text, numeric or logical. As long as the data is always a logical it'll work
just fine. If there might be mixed data types I would use one of Aladins
suggestions (the shortest one),

Biff