Double Match formula...

[eXecutioner28]

Hi

I have a big problem and need immediate assistance, please. I am using this
formula for single MATCH problem: =INDEX(rukohvati1;MATCH(C5;rukohvati;0);2)

this "rukohvati1" is on a sheet in this document on which I have three
columns, so it must give values of column 2. But now I want to match C5 with
rukohvati, but also C6 with another one, let say "nesto" to have something
like this =INDEX(rukohvati;MATCH(C5;rukohvati;MATCH(C6;nesto);0);2).

but this wont work. I need to combine condition 1 (C5) and condition 2 (C6).

if someone can help please do asap, I need this for work. And if u want I
can send you this xls file.

thank you very much

 

[eXecutioner28]

to get the idea here is what I have:


2-SIDED POCKET 140x200 0,0040 IZRADA RUKOHVATA
CHAMBORD 140x190 0,0071 IZRADA RUKOHVATA
2-SIDED POCKET 140x200 0,0025 REZANJE
CHAMBORD 140x190 0,0035 REZANJE

so this is on one sheet together (there are more of this operations like
"IZRADA RUKOHVATA" and "REZANJE" but you get the idea). Now I want on a new
sheet to create a selection where I select model -> CHAMBORD 140x190 and
operation -> REZANJE to get value of 0,0035. But also when I choose different
operation for CHAMBORD 140x190 like "IZRADA RUKOHVATA" to get value of
0,0071.

I know only how to do with one MATCH function. With two MATCH functions I
can get anything...

please help

 

[Teethless mama]

F1: holds CHAMBORD 140X190
G1: holds IZRADA RUKOHVATA

=INDEX(B2:B100,MATCH(F1&G1,INDEX(A2:A100&C2:C100,0),0))

 

[Dave Peterson]

Saved from a previous post:

If you want exact matches for just two columns (and return a value from a
third), you could use:

=index(othersheet!$c$1:$c$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100),0))

(all in one cell)

This is an array formula. Hit ctrl-shift-enter instead of enter. If you do it
correctly, excel will wrap curly brackets {} around your formula. (don't type
them yourself.)

Adjust the range to match--but you can only use the whole column in xl2007.

This returns the value in othersheet column C when column A and B (of
othersheet) match A2 and B2 of the sheet with the formula.

And you can add more conditions by just adding more stuff to that product
portion of the formula:

=index(othersheet!$d$1:$d$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100)
*(c2=othersheet!$c$1:$c$100),0))

 

[eXecutioner28]

you the man... tried it and worked. Will try to use this one in the future,
but if u see me in a problem again please help....

bye

 

[eXecutioner28]

Dave, thank you for you help and effort - will try your formula as well...

bye