Does anyone have a template to convert Kilos to Pounds & Ounces

[Pagie]

I am looking for a template that converts kilos to Pounds and Ounces to the
nearest ounce. If anyone can help I'd be most grateful
Regards
Ray Page

 

[Don Guillett]

Have you tried the CONVERT function

 

[Mike H]

Hi,

Excel has an inbuilt fubction called CONVERT. Have a look in help.

Mike

 

[Gary''s Student]

With kilos in A1, In B1 & C1:

=ROUND(convert(A1,"kg","lbm"),0)
=ROUND(16*(convert(A1,"kg","lbm")-B1),0)

so 17 kilos will show as 37 lbs 8 ozs

 

[Rick Rothstein]

You shouldn't use ROUND for the conversion to pounds as that can round a
value (with a fraction greater than 0.5) up when you don't want it to (try
19 kilograms to see the problem). Here are the formulas I would use (I like
my second one instead of yours as it only relies on the cell with the
kilogram value in it meaning it can be placed anywhere without having to
attend to the B1 reference to the pounds value...

=INT(CONVERT(A1,"kg","lbm"))
=ROUND(16*MOD(CONVERT(A1,"kg","lbm"),1),0)

 

[Gary''s Student]

Good advice Thanks

 

[Chip Pearson]

You can use the DOLLARDE to covert kgs to lbs.oz where the integer
portion of the result is the number of pounds and the fractional
portion is the number of ounces. E.g.,

10.01 = 10 lbs 01 oz
10.10 = 10 lbs 10 oz

=DOLLARFR(A1*2.2046,16)

where A1 is the kg value. Note that, for example, a result of 10.01
does not mean 10 + (1/100) lbs, it means 10 lbs + 01 oz. Similarly,
10.10 does not mean 10 + (1/10), it means 10 lbs + 10 oz.

To convert these values to values that can be used in calculations,
use

=DOLLARDE(B1,16)

These functions take their name from their use in working the stock
prices which are often expressed in eighthts of a dollar.


In Excel 2003 and earlier, you'll need to load the Analysis Tool Pack.
Go to the Tools menu, choose Add Ins, and check "Analysis Tool Pack"
in the list. In Excel 2007 and later, these functions are native to
Excel and do not require an add-in.

Cordially,
Chip Pearson
Microsoft Most Valuable Professional
Excel Product Group, 1998 - 2009
Pearson Software Consulting, LLC
www.cpearson.com
(email on web site)