Display formula in all worksheets

[slc]

Need help...

My workbook has multiple worksheets. I am trying to create a macro
that will display the formula in all the worksheets with 1-step. The
following macro don't seems to work. Thanks for your help.


Sub ShowFormula()
'
' Display formula instead of value in all worksheets
'
Dim Sh As Worksheet
'
For Each Sh In ActiveWorkbook.Worksheets
ActiveWindow.DisplayFormulas = True
Next
End Sub

 

[mangesh_yadav]

This worked for me.

Sub MyDisplayFormula()

ActiveWindow.DisplayFormulas = True

End Sub

Manges

 

[Norman Jones]

Hi SLC,

Your sub fails because whilst you cycle through the worksheets, the active
window remains unchanged.

Try:

'========================>>
Public Sub ShowFormula()

'\\ Display formula instead of value in all worksheets

Dim SH As Worksheet
Dim SHcurrent As Worksheet

Set SHcurrent = ActiveSheet

Application.ScreenUpdating = False

For Each SH In ActiveWorkbook.Worksheets
SH.Activate
ActiveWindow.DisplayFormulas = True
Next

SHcurrent.Activate

Application.ScreenUpdating = True

End Sub
'<<========================

And, anticipating your next question...:


'========================>>
Public Sub HideFormulas()

'\\ Restore value display in all worksheets

Dim SH As Worksheet
Dim SHcurrent As Worksheet

Set SHcurrent = ActiveSheet

Application.ScreenUpdating = False

For Each SH In ActiveWorkbook.Worksheets
SH.Activate
ActiveWindow.DisplayFormulas = False
Next

SHcurrent.Activate

Application.ScreenUpdating = True

End Sub

'<<========================