crytographic services disfunction

  • Thread starter Thread starter Guest
  • Start date Start date
G

Guest

Win XP Home SP1 with all critical updates except SP2 installed.

McAfee native & Panda on line find no viri.

Spybot 1.3 & AASE, each with latest updates find nothing.

I am unable to access some sites. I can fix it by one of the following
methods, but after a couple of days, the problem returns.

Can someone tell my why this recurs and / or what I can do to prevent this
from happening again & again?



Ensure that the "Cryptographic Services" service is running on your
computer. To do this, open Control Panel, Administrative Tools, Services.
Select "Cryptographic Services" from the list of names. Right-click this
service and select Properties. If the service is not shown as "Started", you
can start it by clicking the Start button. You should also set the Startup
type to Automatic so that it will be running when needed in future. Close the
Services control panel and try installing the service pack or security patch.
If the "Cryptographic Services" service was already running, stop the
service by clicking the Stop button, then using Windows Explorer, locate the
folder Windows\System32\catroot2 and rename it to something like xcatroot.
Now restart "Cryptographic Services" by clicking the Start button, and try
installing the service pack or security patch.
If the service pack or security patch still fails to install, stop the
"Cryptographic Services" service again. Open a command prompt window (click
Start, Run, type cmd and hit Enter) and then type the following commands:

regsvr32 softpub.dll
regsvr32 wintrust.dll
regsvr32 initpki.dll
regsvr32 dssenh.dll
regsvr32 rsaenh.dll
regsvr32 gpkcsp.dll
regsvr32 sccbase.dll
regsvr32 slbcsp.dll
regsvr32 cryptdlg.dll

Restart "Cryptographic Services" by clicking the Start button again, and try
installing the service pack or security patch.
Ensure that the "Cryptographic Services" service is running on your
computer. To do this, open Control Panel, Administrative Tools, Services.
Select "Cryptographic Services" from the list of names. Right-click this
service and select Properties. If the service is not shown as "Started", you
can start it by clicking the Start button. You should also set the Startup
type to Automatic so that it will be running when needed in future. Close the
Services control panel and try installing the service pack or security patch.
If the "Cryptographic Services" service was already running, stop the
service by clicking the Stop button, then using Windows Explorer, locate the
folder Windows\System32\catroot2 and rename it to something like xcatroot.
Now restart "Cryptographic Services" by clicking the Start button, and try
installing the service pack or security patch.
If the service pack or security patch still fails to install, stop the
"Cryptographic Services" service again. Open a command prompt window (click
Start, Run, type cmd and hit Enter) and then type the following commands:

regsvr32 softpub.dll
regsvr32 wintrust.dll
regsvr32 initpki.dll
regsvr32 dssenh.dll
regsvr32 rsaenh.dll
regsvr32 gpkcsp.dll
regsvr32 sccbase.dll
regsvr32 slbcsp.dll
regsvr32 cryptdlg.dll

Restart "Cryptographic Services" by clicking the Start button again, and try
installing the service pack or security patch.


********

Method 4: Reregister DLL files that are associated with Cryptographic Services
To register .dll files that are associated with Cryptographic Services,
follow these steps: 1. Click Start, and then click Run.
2. In the Open box, type cmd, and then click OK.
3. At the command prompt, type the following commands, pressing ENTER after
each line:

Note Click OK if you are prompted.

Note Microsoft Windows 2000 does not include the Sccbase.dll file. If you
are running a version of Windows 2000, omit the Sccbase.dll file.
regsvr32 softpub.dll
regsvr32 /u wintrust.dll
regsvr32 /u initpki.dll
regsvr32 /u dssenh.dll
regsvr32 /u rsaenh.dll
regsvr32 /u gpkcsp.dll
regsvr32 /u sccbase.dll
regsvr32 /u slbcsp.dll
regsvr32 /u cryptdlg.dll
regsvr32 /u softpub.dll
exit
4. Restart your computer.
5. Click Start, click Run, type cmd in the Open box, and then click OK.
6. At the command prompt, type the following commands (press ENTER after
each command).

Note Click OK if you are prompted.

Note Microsoft Windows 2000 does not include the Sccbase.dll file. If you
are running a version of Windows 2000, omit the Sccbase.dll file.
regsvr32 softpub.dll
regsvr32 wintrust.dll
regsvr32 initpki.dll
regsvr32 dssenh.dll
regsvr32 rsaenh.dll
regsvr32 gpkcsp.dll
regsvr32 sccbase.dll
regsvr32 slbcsp.dll
regsvr32 cryptdlg.dll
regsvr32 softpub.dll
exit


http://www.kbalertz.com/Feedback.aspx?kbNumber=822798

Thanks.
WC
 
Wiley said:
Win XP Home SP1 with all critical updates except SP2 installed.

McAfee native & Panda on line find no viri.

Spybot 1.3 & AASE, each with latest updates find nothing.

I am unable to access some sites. I can fix it by one of the following
methods, but after a couple of days, the problem returns.

Can someone tell my why this recurs and / or what I can do to prevent
this from happening again & again?
Click to expand...

I don't know the answers to your question, but to save some time
when you need to do this, I have already created a batch file that
does the steps below.

http://www.michna.com/kb/WxSP2.htm#Cannot_install_Service_Pack_2

Look for fixdb.bat under "Error 0x800710D9 Unable to read from
or write to the database". Download and run it.
 
Wiley said:
I appreciate your effort, Torgeir.

Your link is dead >> Page cannot be displayed.
Click to expand...
Hi

Here is a copy:

Place the text below in a .bat (batch) file (e.g. paste it into a new
notepad document and save it with e.g. the name fixdb.bat)

Then run the batch file by double clicking on it.

You should run the batch file just after a reboot of the computer (as
the first thing).

The batch file will tell you when it is finished.

Start batch file:
--------------------8<----------------------

@echo off
:: Batch file that tries to remedy error # 800710D9
:: "Unable to read from or write to the database".
::
:: It will fix cryptographic errors as well
::
:: Author: Torgeir Bakken
:: Date: 2004-08-30

:: Stop the Cryptographic service
%SystemRoot%\System32\net.exe stop CryptSvc

:: Rename all log files in the %SystemRoot%\Security folder
FOR %%a in (%SystemRoot%\Security\*.log) DO move /y %%a %%a.old

:: Rename the %SystemRoot%\System32\CatRoot2 folder
move /y %SystemRoot%\System32\CatRoot2 %SystemRoot%\System32\CatRoot2old

IF not exist %SystemRoot%\System32\CatRoot2 GOTO CONT01

:: In case the folder rename failed because of locked files
:: rename all log files in the %SystemRoot%\System32\CatRoot2 folder
FOR %%a in (%SystemRoot%\System32\CatRoot2\*.log) DO move /y %%a %%a.old
SET catroot2locked=True

:CONT01
cls
echo.
echo Please wait, this might take some time...

:: Unregister DLL files that are associated with Cryptographic Services
CD /D %SystemRoot%\System32
start /wait regsvr32.exe /s /u softpub.dll
start /wait regsvr32.exe /s /u wintrust.dll
start /wait regsvr32.exe /s /u initpki.dll
start /wait regsvr32.exe /s /u dssenh.dll
start /wait regsvr32.exe /s /u rsaenh.dll
start /wait regsvr32.exe /s /u gpkcsp.dll
start /wait regsvr32.exe /s /u sccbase.dll
start /wait regsvr32.exe /s /u slbcsp.dll
start /wait regsvr32.exe /s /u cryptdlg.dll

:: Reregister DLL files that are associated with Cryptographic Services
start /wait regsvr32.exe /s softpub.dll
start /wait regsvr32.exe /s wintrust.dll
start /wait regsvr32.exe /s initpki.dll
start /wait regsvr32.exe /s dssenh.dll
start /wait regsvr32.exe /s rsaenh.dll
start /wait regsvr32.exe /s gpkcsp.dll
start /wait regsvr32.exe /s sccbase.dll
start /wait regsvr32.exe /s slbcsp.dll
start /wait regsvr32.exe /s cryptdlg.dll

:: Configure and start the Cryptographic service
%SystemRoot%\system32\sc.exe config CryptSvc start= auto
:: Start the Cryptographic Service
%SystemRoot%\system32\net.exe start CryptSvc
cls

echo.
If "%catroot2locked%"=="True" GOTO CONT02
echo Finished, please reboot the computer and then try to install SP2 again...

GOTO END
:CONT02
echo Please run the batch file again with a newly restarted computer...
echo (but if it is newly restarted, just do a reboot and then try
echo to install SP2 again)...
GOTO END

:END
echo.
pause

--------------------8<----------------------
 
Back
Top