This is my standard reply to this question
Let's start by defining the range A1:A20 to talk specifics.
Bob,John,Bob,Bob,John,John,Bob,Bill,Bill,Max
or data in just A1:A10
The basic formula to count unique items is
=SUMPRODUCT(1/COUNTIF($A$1:$A$10,$A$1:$A$10))
The COUNTIF($A$1:$A$10,$A$1:$A$10) part of the formula builds an array of
the number of occurrences of each item, in this case{4;3;4;4;3;3;4;2;2;1}.
As can be seen, each occurrence of the repeated value is counted, so there
are four occurrences of Bob in the array. There will always be the same
number of occurrences of value as the count of that value, unless two or
more items are repeated the same number of times, in which case it will be
some multiple of that count.
Thus the item that is repeated 4 times has 4 instances of that count,
dividing 1 by the count of 4, gives 0.25 4 times. The full array of values
is
{0.25;0.333333333333333;0.25;0.25;0.333333333333333;0.333333333333333;0.25;0
..5;0.5;1}.
The item that repeats 4 times sums to 1. The item that repeats 3 times also
sums to 1. It should be clear from this that every value works in the same
way and sums to 1. In other words, 1 is returned for every unique item. The
sum of these values becomes the count of unique items.
As our test range is A1:A20, and some of the items in A1:A20 are blank,
extending this formula to A1:A20 would return a #DIV/0! Error.
The reason for the error is blank cells in the full range A1:A20. Each blank
cell returns a 0 value from the COUNTIF formula, which gives the #DIV/0!
Error when divided into 1.
The solution to this is to force it to count the empty cells as well, and
not return a zero. Adding &"" to the end of the COUNTIF formula forces a
count of the blanks.
This addition on its own removes the #DIV/0! error, but will cause the
blanks to be counted as a unique item. A further addition to the formula
resolves this by testing for those blanks. Instead of dividing the array of
counts into 1 each time, adding the test creates an array of TRUE/FALSE
values to be divided by the equivalent element in the counts array. Each
blank will resolve to FALSE in the dividend array, and the count of the
blanks in the divisor array. The result of this will be 0, so the blanks do
not get counted.
--
HTH
Bob Phillips
(replace somewhere in email address with gmail if mailing direct)
Biff,
That's brilliant! Some time ago, I found the following array formula
suggested by an expert.
{=SUM(COUNTIF(A1:A15,A1:A15)/IF(NOT(COUNTIF(A1:A15,A1:A15)),1,COUNTIF(A1:A15
,A1:A15))^2)}
Like your formula, it takes care of blanks in the array as well. Can you
confirm that both your formula and the above formula do exactly the same
thing i.e. count unique text and numeric values in a range which may contain
blanks. If yes, I'll replace the above with your formula.
Regarding the formula
=SUMPRODUCT((A1:A15<>"")/COUNTIF(A1:A15,A1:A15&""))
can you explain the &"" part please? I know if I remove &"" I will get the
#DIV/0! error. But I can't tell from "evaluate formula" what &"" is doing?
One more question:-
I know from my record and JMB's comment that this formula
=SUMPRODUCT(1/COUNTIF(A1:A15,A1:A15))
will give an error when there is a blank in the array. When I change it to
=SUMPRODUCT(1/COUNTIF(A1:A15,A1:A15&""))
I get a result which counts the blank(s) as well. I guess if I want blanks
counted, I can use this formula, right?
Another alternative to count unique records is to use Advanced filter,
unique records, and COUNTA. This doesn't require any analysis and
understanding.
Biff, I look forward to your guidance. Thanks!
Epinn
Try this:
=SUMPRODUCT(--(A1:A9<>"")/COUNTIF(A1:A9,A1:A9&""))
Biff
