Countind date between two dates - formula results

[Guest]

I have a spreadsheet that has clients names and then the date that I
submitted the business for them i.e

Mr Jones 12/12/2006 Abbey
Mrs Smith 12/01/2007 Natwest

What is the best way to count all the submitted business in 1 month say for
January only. Also how would i count all the Abbey cases in say 2007, or 2006.

I need this as a formula so that I can populate graphes etc with it.

 

[Guest]

==SUMPRODUCT(--(B2:B100<>""),--(MONTH(B2:B100=1)),--(YEAR(B2:B100=2007)))

=SUMPRODUCT(--(B2:B100<>""),--(MONTH(B2:B100=1)),--(YEAR(B2:B100=2007)))

=SUMPRODUCT(--(B2:B100<>""),--(C2:C100="Abbey"),--(YEAR(B2:B100=2007)))

It's better to put the parameters in cellS:

=SUMPRODUCT(--(B2:B100<>""),--(C2:C100=X1),--(YEAR(B2:B100=X2)))

X1="Abbey"
X2=2007

HTH

 

[Guest]

A rather crude way, yet effective, is to create a formula in column D that
concatenates the year from column B and the client from column C. THe
formula is:

=year(b2)&c2

This would yield "2006Abbey". Then copy that down all rows for your data.
Once complete, in another cell you can enter the formula:

=countif(D,"2006Abbey")

Hope this helps!

 

[Guest]

Hi Toppers,

I have used the bottom formula and thats almost perfect, except the cell has
the complete date in it, so 2007 is only part of the cell, i.e my cell is
01/03/2007 so I need to pick the year only part of the date.

 

[T. Valko]

To count entries for the month of *January*. This will include *all* years.

=SUMPRODUCT(--(ISNUMBER(B1:B9)),--(MONTH(B1:B9)=1))

To count entries for *any other month*:

=SUMPRODUCT(--(MONTH(B1:B9)=month_number))

To count for January of a specific year (if you might be counting for
January 1900 include the ISNUMBER test. Empty cells evaluate as date January
0 1900):

=SUMPRODUCT(--(MONTH(B1:B9)=1),--(YEAR(B1:B9)=year_number))

Or:

=SUMPRODUCT(--(TEXT(B1:B9,"mmmyyyy")="Jan2007"))

To count entries of "Abbey" for years 2006, 2007 (includes *all* months):

=SUMPRODUCT((YEAR(B1:B9)={2006,2007})*(C1:C9="Abbey"))

 

[Guest]

That formula will still work Mark. He omitted a ")" in it though after the
2nd B100 reference. The correct formula should read:

=SUMPRODUCT(--(B2:B100<>""),--(C2:C100=X1),--(YEAR(B2:B100)=X2)))

The YEAR function only looks at the YEAR in the full date, so that is what
you need.

 

[Guest]

That's what the formula does ... selects year=2007 from a date field.

Did you try it?

 

[Guest]

I have tried this toppers, it comes back with the result FALSE in the cell,
this is the formula
=SUMPRODUCT(--(E25:E28<>""),--(G25:G28="Abbey"),--(YEAR(F25:F28=2005)))

and the data

E F G
Dave 01/03/2005 Abbey
Gary 01/03/2006 Abbey
Jane 02/03/2005 Abbey
Gaz 05/03/2005 Abbey

I think this should return the result in my cell of 3

 

[Guest]

Biff, you the man. thanks a lot - thats solved my headache

 

[T. Valko]

=SUMPRODUCT(--(E25:E28<>""),--(G25:G28="Abbey"),--(YEAR(F25:F28=2005)))

Try it like this:

=SUMPRODUCT(--(E25:E28<>""),--(G25:G28="Abbey"),--(YEAR(F25:F28)=2005))

 

[Guest]

Mark,
Mea culpa ... I missed off a bracket. See Biff's reply

 

[Guest]

oh my god, it works brilliantly if i am on the same sheet, but i want to look
at data from another worksheet, just a tab along, I have replace the
appropriate date but now it doesnt like the formula. This is what I have at
the mo(Mortgages being another worksheet but int the same book). It is the
same formula that works but merely grabbing data elsewhere????????????

=SUMPRODUCT(--(Mortgages!C176:C186<>""),--(Mortgages!F174:F187="Abbey"),--(YEAR(Mortgages!K174:K185)=2007))

C = the name of client
F = the company
K = The date submitted


aaaaaaaaaaaaaaaaaaaaargh

 

[Guest]

The array (range) sizes must be the same size when using SUMPRODUCT.

=SUMPRODUCT(--(Mortgages!C174:C187<>""),--(Mortgages!F174:F187="Abbey"),--(YEAR(Mortgages!K174:K187)=2007))

???