# Convert Week number into Month

K

#### KT

I have a worksheet with values for year and week number. I need to convert
these to the descriptive month name. Some weeks cross month ends, but this
is okay, I just need a single value for each record. It could be the month
of the first day of each week number. Using Excel 2003.

L

#### Lars-Åke Aspelin

I have a worksheet with values for year and week number. I need to convert
these to the descriptive month name. Some weeks cross month ends, but this
is okay, I just need a single value for each record. It could be the month
of the first day of each week number. Using Excel 2003.

If your year is in cell A1 and you week number is in cell B2, try the
following formula:

=MONTH(DATE(A1,1,MATCH(TRUE,WEEKNUM(DATE(A1,1,ROW(A1:A366)),2)=B1,0)))

Note: This is an array formula that should be confirmed by
CTRL+SHIFT+ENTER rather than just ENTER.

Note 2: WEEKNUM does not support European standard for week number,
see
http://office.microsoft.com/en-us/excel/HP052093371033.aspx

If you use the European standard for week numbers, you have to put
some more logic into the formula to handle the case, like this year,
where the first few days of the year is not week number 1.
In Europe January 1-3 of 2010 is week number 53.

Hope this helps / Lars-Åke

S

#### Steve Dunn

=TEXT(MONTH(DATE(A1,1,MATCH(B1,INDEX(WEEKNUM(DATE(A1,1,ROW(A1:A366)),2),),0))),"MMMM")

Which does *not* need to be array entered.

HTH
Steve D.

L

#### Lars-Åke Aspelin

Remove the call to MONTH() and the formula will work better.
=TEXT(DATE(A1,1,MATCH(B1,INDEX(WEEKNUM(DATE(A1,1,ROW(A1:A366)),2),),0)),"MMMM")

Lars-Åke

L

#### Lars-Åke Aspelin

If your year is in cell A1 and you week number is in cell B2, try the
following formula:

=MONTH(DATE(A1,1,MATCH(TRUE,WEEKNUM(DATE(A1,1,ROW(A1:A366)),2)=B1,0)))

Note: This is an array formula that should be confirmed by
CTRL+SHIFT+ENTER rather than just ENTER.

Note 2: WEEKNUM does not support European standard for week number,
see
http://office.microsoft.com/en-us/excel/HP052093371033.aspx

If you use the European standard for week numbers, you have to put
some more logic into the formula to handle the case, like this year,
where the first few days of the year is not week number 1.
In Europe January 1-3 of 2010 is week number 53.

Hope this helps / Lars-Åke

I made a typo there. The week number is in cell B1 (not B2) of course.

Lars-Åke

A

#### alovell

This needs "ROW(A\$1:A\$366)" or you will get things like 6 weeks in January and the formula gets exhausted while still in November after 53 weeks.