Computing full Months

[Guest]

Having trouble writing a formula that will add 3 full months to a hire date
and the result starts with day 1 in the month.
Example:
Hire Date 1/10/2005
The 3 "full months after hire are Feb, Mar, Apr.
Want result to be May 1, 2005.
Can anyone help?

 

[Bernd Plumhoff]

=IF(DAY(A1)=1,DATE(YEAR(A1),MONTH(A1)+3,1),DATE(YEAR(A1),MONTH(A1)+4,1))

HTH,
Bernd

 

[Guest]

I can think of 2 ways to go with this, depending on how you want the first of
the month treated:
=EOMONTH($A$1-1,3)+1
OR
=EOMONTH($A$1,3)+1

Note: Per Excel Help:If this function is not available, and returns the
#NAME? error, install and load the Analysis ToolPak add-in.


Does that help?

 

[Don Guillett]

One way
=DATE(YEAR(H3),MONTH(H3)+4,1)

 

[Don Guillett]

or
=DATE(YEAR(A1),MONTH(A1)+IF(DAY(A1)=1,3,4),1)

 

[Ron Rosenfeld]

Having trouble writing a formula that will add 3 full months to a hire date
and the result starts with day 1 in the month.
Example:
Hire Date 1/10/2005
The 3 "full months after hire are Feb, Mar, Apr.
Want result to be May 1, 2005.
Can anyone help?

Assuming that if Hire Date is 1 Jan 2005, then the result would be 1 Apr 2005;
but if the Hire Date is after the first of Jan, then the result would be 1 May
2005:

=DATE(YEAR(A1-1),MONTH(A1-1)+4,1)


--ron