Combine Two Arrays Into One. Tough.

[ryguy7272]

I have a function that alphabetizes an array of text:

=INDEX($A$1:$A$10,MATCH(ROW(A1),COUNTIF($A$1:$A$10,"<="&$A$1:$A$10),))
CSE-entered

I also have a function that eliminates dupes:

=IF(ISERR(SMALL(IF(MATCH($A$10:$A$16,$A$10:$A$16,0)=ROW(INDIRECT("1:"&ROWS($A$10:$A$16))),MATCH($A$10:$A$16,$A$10:$A$16,0)),ROWS($10:10))),"",INDEX($A$10:$A$16,SMALL(IF(MATCH($A$10:$A$16,$A$10:$A$16,0)=ROW(INDIRECT("1:"&ROWS($A$10:$A$16))),MATCH($A$10:$A$16,$A$10:$A$16,0)),ROWS($10:10))))
CSE-entered

Now, I’m wondering if I can combine the two. That will take some hack work.
Also, I’m wondering how much this will slow down the workbook. There are
about 8-9 sheets in there and an array formula like this will probably make
the thing crawl, right. Anyway, my question is how do I combine there two
arrays?
Thanks,
Ryan--

 

[T. Valko]

I have a function that alphabetizes an array of text:

I also have a function that eliminates dupes
I'm wondering if I can combine the two

Try these...

Does not work if there are empty cells within the range.

Data in the range A1:A10.

Enter this array formula** in C1:

=INDEX(A1:A10,MATCH(0,COUNTIF(A1:A10,"<"&A1:A10),0))

Enter this array formula** in C2 and copy down to C10:

=IF(COUNTIF(A$1:A$10,">"&C1),INDEX(A$1:A$10,MATCH(COUNTIF(A$1:A$10,"<="&C1),COUNTIF(A$1:A$10,"<"&A$1:A$10),0)),"")

** array formulas need to be entered using the key combination of
CTRL,SHIFT,ENTER (not just ENTER). Hold down both the CTRL key and the SHIFT
key then hit ENTER.

 

[ryguy7272]

That is soooooo sweet! Thanks so much!!
Ryan---

 

[T. Valko]

You're welcome. Thanks for the feedback!