Autofill hyperlinks

N

NannyKay

Can you tell me how to autofill a hyperlink formula so that both the file
path and the friendly name change incrementally? I'm using the hyperlink
function, and need to copy it down so that the file name changes (dec 8.pdf,
dec 9.pdf...) and the friendly name also changes (Dec 8, Dec 9...)

The formula I am using is: =HYPERLINK("g:\public\DP\dec 7.pdf","Dec 7")

Thank you!
 
P

Pete_UK

Try this:

=HYPERLINK("g:\public\DP\dec "&ROW(A7)&".pdf","Dec "&ROW(A7))

ROW(A7) will return 7, and so will be equivalent to what you have. As
you copy this down, A7 will become A8 and thus return 8, and so on.

Hope this helps.

Pete
 
G

Gary''s Student

In the first cell, enter:

=HYPERLINK("g:\public\DP\dec " & ROWS($1:7) & ".pdf","Dec " & ROWS($1:7))

and copy down. the ROWS() function generates the sequence of increasing
digits.
 
N

NannyKay

Works perfectly!! Thank you VERY much

Gary''s Student said:
In the first cell, enter:

=HYPERLINK("g:\public\DP\dec " & ROWS($1:7) & ".pdf","Dec " & ROWS($1:7))

and copy down. the ROWS() function generates the sequence of increasing
digits.
 
D

Dave Peterson

If you're going to change months, then you could use something like this--and
this relies on the row that the formula is placed. So you may have to change
that adjustment to what you want.

I put this in Row 1:
=HYPERLINK("g:\public\DP\"&TEXT(DATE(2009,12,7)+ROW()-1,"mmm d")&".pdf",
TEXT(DATE(2009,12,7)+ROW()-1,"mmm d"))

so date(2009,12,7)+row()-1 starts on the date that I want (Dec 7).

If your first formula should return Dec 7 and is entered in row 22, you could
use:

=HYPERLINK("g:\public\DP\"&TEXT(DATE(2009,12,7)+ROW()-22,"mmm d")&".pdf",
TEXT(DATE(2009,12,7)+ROW()-22,"mmm d"))
 
G

Gord Dibben

How far do you want to go?

This construct will take you from Dec 7 to Dec 31 when entered in A1 and
dragged down to A25

=HYPERLINK("g:\public\DP\dec "&ROW(7:7)&".pdf","Dec "&ROW(7:7)&"")

Would you have more that fall into the next month or months?


Gord Dibben MS Excel MVP
 

Ask a Question

Want to reply to this thread or ask your own question?

You'll need to choose a username for the site, which only take a couple of moments. After that, you can post your question and our members will help you out.

Ask a Question

Top