Adding pictures to records

[Guest]

I have a large table of subscribers. I also have .jpgs picturing each of my
subscribers named exactly the same as the name field in the main table. Can
I add a new field to the main table and link it with the appropriate .jpg
file? If the answer is yes, how do I do it?
Many thanks for your input.

 

[doodle]

Lyndie,

I would not add them to your main table, but create a separate table
for your pictures. I would also suggest not saving the pictures, but
rather the network path to the pictures.

Table suggestion: tblPictures
txtRefID (Key Field)
txtImagePath (text)

You can then create a subform from your main form that you can use to
browse and view pictures. sbfPictures

1.Create a text box on the subform named ImagePath_1 with the control
source of txtImagePath from tblPictures

After Update event for the text box:

Private Sub ImagePath_1_AfterUpdate()
'This code will link the picture path to the picture image
On Error Resume Next

Me![ImageFrame_1].Picture = Me![ImagePath_1]
Me.Refresh

End Sub

2. Create an Image Frame on the subform named ImageFrame_1
If you would like to see a default picture, browse for a picture in the
Picture property of the frame.

3. Create a command button on the subform named cmdBrowse_1

On Click event for the cmdButton:

Private Sub cmdBrowse_1_Click()
On Error Resume Next
Me.ImagePath_1 = GetOpenFile()

'This code will link the picture path to the picture image
On Error Resume Next

Me![ImageFrame_1].Picture = Me![ImagePath_1]
Me.Refresh

End Sub

4. On current event for the Form should be:

'This code will link the picture path to the picture image
On Error Resume Next

Me![ImageFrame_1].Picture = Me![ImagePath_1]
End Sub

5. On Unload event for the form should be:

Private Sub Form_Unload(Cancel As Integer)
[ImagePath_1].SetFocus
End Sub

6. Create basFileOpenDialog using this code:
(I didn't write this, I don't remember who it came from but thanks
again )

Option Compare Database
Option Explicit

Type tagOPENFILENAME
lStructSize As Long
hwndOwner As Long
hInstance As Long
strFilter As String
strCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
strFile As String
nMaxFile As Long
strFileTitle As String
nMaxFileTitle As Long
strInitialDir As String
strTitle As String
Flags As Long
nFileOffset As Integer
nFileExtension As Integer
strDefExt As String
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type

Declare Function aht_apiGetOpenFileName Lib "comdlg32.dll" _
Alias "GetOpenFileNameA" (OFN As tagOPENFILENAME) As Boolean

Declare Function aht_apiGetSaveFileName Lib "comdlg32.dll" _
Alias "GetSaveFileNameA" (OFN As tagOPENFILENAME) As Boolean
Declare Function CommDlgExtendedError Lib "comdlg32.dll" () As Long

Global Const ahtOFN_READONLY = &H1
Global Const ahtOFN_OVERWRITEPROMPT = &H2
Global Const ahtOFN_HIDEREADONLY = &H4
Global Const ahtOFN_NOCHANGEDIR = &H8
Global Const ahtOFN_SHOWHELP = &H10
' You won't use these.
'Global Const ahtOFN_ENABLEHOOK = &H20
'Global Const ahtOFN_ENABLETEMPLATE = &H40
'Global Const ahtOFN_ENABLETEMPLATEHANDLE = &H80
Global Const ahtOFN_NOVALIDATE = &H100
Global Const ahtOFN_ALLOWMULTISELECT = &H200
Global Const ahtOFN_EXTENSIONDIFFERENT = &H400
Global Const ahtOFN_PATHMUSTEXIST = &H800
Global Const ahtOFN_FILEMUSTEXIST = &H1000
Global Const ahtOFN_CREATEPROMPT = &H2000
Global Const ahtOFN_SHAREAWARE = &H4000
Global Const ahtOFN_NOREADONLYRETURN = &H8000
Global Const ahtOFN_NOTESTFILECREATE = &H10000
Global Const ahtOFN_NONETWORKBUTTON = &H20000
Global Const ahtOFN_NOLONGNAMES = &H40000
' New for Windows 95
Global Const ahtOFN_EXPLORER = &H80000
Global Const ahtOFN_NODEREFERENCELINKS = &H100000
Global Const ahtOFN_LONGNAMES = &H200000

Function TestIt()
Dim strFilter As String
Dim lngFlags As Long
'strFilter = ahtAddFilterItem(strFilter, "Access Files (*.mda,
*.mdb)","*.MDA;*.MDB")
strFilter = ahtAddFilterItem(strFilter, "JPG Files (*.jpg)",
"*.JPG")
strFilter = ahtAddFilterItem(strFilter, "GIF Files (*.gif)",
"*.GIF")
strFilter = ahtAddFilterItem(strFilter, "Bitmap Files (*.bmp)",
"*.BMP")
strFilter = ahtAddFilterItem(strFilter, "All Files (*.*)", "*.*")
'strFilter = ahtAddFilterItem(strFilter, "dBASE Files (*.dbf)",
"*.DBF")
'strFilter = ahtAddFilterItem(strFilter, "Text Files (*.txt)",
"*.TXT")
MsgBox "You selected: " & ahtCommonFileOpenSave(InitialDir:="C:\",
_
Filter:=strFilter, FilterIndex:=3, Flags:=lngFlags, _
DialogTitle:="Hello! Open Me!")
' Since you passed in a variable for lngFlags,
' the function places the output flags value in the variable.
Debug.Print Hex(lngFlags)
End Function

Function GetOpenFile(Optional varDirectory As Variant, _
Optional varTitleForDialog As Variant) As Variant
' Here's an example that gets an Access database name.
Dim strFilter As String
Dim lngFlags As Long
Dim varFileName As Variant
' Specify that the chosen file must already exist,
' don't change directories when you're done
' Also, don't bother displaying
' the read-only box. It'll only confuse people.
lngFlags = ahtOFN_FILEMUSTEXIST Or _
ahtOFN_HIDEREADONLY Or ahtOFN_NOCHANGEDIR
If IsMissing(varDirectory) Then
varDirectory = ""
End If
If IsMissing(varTitleForDialog) Then
varTitleForDialog = ""
End If

' Define the filter string and allocate space in the "c"
' string Duplicate this line with changes as necessary for
' more file templates.
'strFilter = ahtAddFilterItem(strFilter,"Access (*.mdb)",
"*.MDB;*.MDA")
strFilter = ahtAddFilterItem(strFilter, "JPG Files (*.jpg)",
"*.JPG")
strFilter = ahtAddFilterItem(strFilter, "GIF Files (*.gif)",
"*.GIF")
strFilter = ahtAddFilterItem(strFilter, "Bitmap Files (*.bmp)",
"*.BMP")
strFilter = ahtAddFilterItem(strFilter, "All Files (*.*)", "*.*")

' Now actually call to get the file name.
varFileName = ahtCommonFileOpenSave( _
OpenFile:=True, _
InitialDir:=varDirectory, _
Filter:=strFilter, _
Flags:=lngFlags, _
DialogTitle:=varTitleForDialog)
If Not IsNull(varFileName) Then
varFileName = TrimNull(varFileName)
End If
GetOpenFile = varFileName
End Function

Function ahtCommonFileOpenSave( _
Optional ByRef Flags As Variant, _
Optional ByVal InitialDir As Variant, _
Optional ByVal Filter As Variant, _
Optional ByVal FilterIndex As Variant, _
Optional ByVal DefaultExt As Variant, _
Optional ByVal FileName As Variant, _
Optional ByVal DialogTitle As Variant, _
Optional ByVal hwnd As Variant, _
Optional ByVal OpenFile As Variant) As Variant
' This is the entry point you'll use to call the common
' file open/save dialog. The parameters are listed
' below, and all are optional.
'
' In:
' Flags: one or more of the ahtOFN_* constants, OR'd together.
' InitialDir: the directory in which to first look
' Filter: a set of file filters, set up by calling
' AddFilterItem. See examples.
' FilterIndex: 1-based integer indicating which filter
' set to use, by default (1 if unspecified)
' DefaultExt: Extension to use if the user doesn't enter one.
' Only useful on file saves.
' FileName: Default value for the file name text box.
' DialogTitle: Title for the dialog.
' hWnd: parent window handle
' OpenFile: Boolean(True=Open File/False=Save As)
' Out:
' Return Value: Either Null or the selected filename
Dim OFN As tagOPENFILENAME
Dim strFileName As String
Dim strFileTitle As String
Dim fResult As Boolean
' Give the dialog a caption title.
If IsMissing(InitialDir) Then InitialDir = CurDir
If IsMissing(Filter) Then Filter = ""
If IsMissing(FilterIndex) Then FilterIndex = 1
If IsMissing(Flags) Then Flags = 0&
If IsMissing(DefaultExt) Then DefaultExt = ""
If IsMissing(FileName) Then FileName = ""
If IsMissing(DialogTitle) Then DialogTitle = ""
If IsMissing(hwnd) Then hwnd = Application.hWndAccessApp
If IsMissing(OpenFile) Then OpenFile = True
' Allocate string space for the returned strings.
strFileName = Left(FileName & String(256, 0), 256)
strFileTitle = String(256, 0)
' Set up the data structure before you call the function
With OFN
.lStructSize = Len(OFN)
.hwndOwner = hwnd
.strFilter = Filter
.nFilterIndex = FilterIndex
.strFile = strFileName
.nMaxFile = Len(strFileName)
.strFileTitle = strFileTitle
.nMaxFileTitle = Len(strFileTitle)
.strTitle = DialogTitle
.Flags = Flags
.strDefExt = DefaultExt
.strInitialDir = InitialDir
' Didn't think most people would want to deal with
' these options.
.hInstance = 0
'.strCustomFilter = ""
'.nMaxCustFilter = 0
.lpfnHook = 0
'New for NT 4.0
.strCustomFilter = String(255, 0)
.nMaxCustFilter = 255
End With
' This will pass the desired data structure to the
' Windows API, which will in turn it uses to display
' the Open/Save As Dialog.
If OpenFile Then
fResult = aht_apiGetOpenFileName(OFN)
Else
fResult = aht_apiGetSaveFileName(OFN)
End If

' The function call filled in the strFileTitle member
' of the structure. You'll have to write special code
' to retrieve that if you're interested.
If fResult Then
' You might care to check the Flags member of the
' structure to get information about the chosen file.
' In this example, if you bothered to pass in a
' value for Flags, we'll fill it in with the outgoing
' Flags value.
If Not IsMissing(Flags) Then Flags = OFN.Flags
ahtCommonFileOpenSave = TrimNull(OFN.strFile)
Else
ahtCommonFileOpenSave = vbNullString
End If
End Function

Function ahtAddFilterItem(strFilter As String, _
strDescription As String, Optional varItem As Variant) As String
' Tack a new chunk onto the file filter.
' That is, take the old value, stick onto it the description,
' (like "Databases"), a null character, the skeleton
' (like "*.mdb;*.mda") and a final null character.

If IsMissing(varItem) Then varItem = "*.*"
ahtAddFilterItem = strFilter & _
strDescription & vbNullChar & _
varItem & vbNullChar
End Function

Private Function TrimNull(ByVal strItem As String) As String
Dim intPos As Integer
intPos = InStr(strItem, vbNullChar)
If intPos > 0 Then
TrimNull = Left(strItem, intPos - 1)
Else
TrimNull = strItem
End If
End Function



Hope this helps;

-doodle

 

[Guest]

You simply need to store the path to the file. The picture can then be
loaded into an Image control on a form or report at runtime. As the files
have the same names as the subscriber, which is already a value in a field,
then you only need to store the path to the folder(s) where the files are
located. If they are all in a single folder then you can store this in a
single row table and join this in a query to your main table, e.g.

SELECT Subscribers.*,
PictureLocation.Folder & "\" & SubscriberName AS ImagePath
FROM Subscribers, Pictures;

or for an updatable query:

SELECT *,
DLookup("Folder","PictureLocation") & "\" & SubscriberName AS ImagePath
FROM Subscribers;

where PictureLocation is the table with the path in a column Folder. As in
the first query the tables are not joined on any columns the result will be
the Cartesian product of the two tables, i.e. every row in one will be joined
to every row in the other. As PictureLocation has only one row this will
result in one row per subscriber with the path to their picture in the
ImagePath column. The second uses the DLookup function to get the path; this
makes the query updatable, so should be used if you want to use it as the
basis for a form in which you can edit and/or add records.

In a form you load the pictures into an Image control on the form at runtime
with code like this in the form's Current event procedure:

If Not Me.NewRecord Then
GrabCursor
Me.SubscriberImage.Picture = Me.ImagePath
Me.SubscriberImage,Visible = True
ReturnCursor
Else
Me.SubscriberImage.Viible = False
End If

where SubscriberImage is the name of the Image control. When you first add
the Image control to the form in design view delete the value of its Image
property before saving the form as the property is set at runtime by the
above code.

Loading pictures causes the cursor to jump about a bit, so to keep it in the
same place the code calls the GrabCursor and ReturnCursor procedures which
are in the following module, basCursor, which should be pasted into the
application:

Option Compare Database
Option Explicit

Type POINTAPI
X As Long
Y As Long
End Type

Declare Function GetCursorPos Lib "User32" (lpPoint As POINTAPI) As Long

Declare Function SetCursorPos Lib "User32" (ByVal X As Long, ByVal Y As
Long) As Long

Public lngCursorX As Long, lngCursorY As Long

Public Sub GrabCursor()

Dim dl As Long
Dim pt As POINTAPI

dl = GetCursorPos(pt)
lngCursorX = pt.X
lngCursorY = pt.Y

End Sub

Public Sub ReturnCursor()

SetCursorPos lngCursorX, lngCursorY

End Sub

In a report you do exactly the same but put code in the detail section's
Print event procedure:

Me.SubscriberImage.Picture = Me.ImagePath

You just need the one line because you don't need to cater for a new record
as you do in a form.

With JPEGs you do get a system generated progress message when a file is
loaded. You can suppress this with one of the methods described at:


http://www.mvps.org/access/api/api0038.htm


Ken Sheridan
Stafford, England