adding cells

[just1creation]

can you add more that 30 cells? the cells are in the same column but i
different rows. there are about 50 that i need to add... the formul
that i am using will not let me add more that 30 cells... =SUM(

 

[oldchippy]

can you add more that 30 cells? the cells are in the same column but i
different rows. there are about 50 that i need to add... the formul
that i am using will not let me add more that 30 cells... =SUM( )

Yes you can just select them with the mouse:confused

 

[just1creation]

it will not let me pick more than 30 cells..

 

[oldchippy]

it will not let me pick more than 30 cells...

Hi just1creation

Can you please explain exactly what you are doing, so that I can hel
you

oldchippy :confused

 

[Gord Dibben]

Excel will accept 30 arguments as you have found.

Is there any pattern to the location of the 50 cells?

Can you filter and use the SUBTOTAL function?


Gord Dibben MS Excel MVP

 

[Ragdyer]

If you have some sort of pattern to the cells that you're totaling (every
2nd or 3rd), post back and you'll get a formula to sum them, without having
to type in the individual cell references.

If there is *no* pattern to the cells, simply enclose the formula in
*double* parenthesis's
=SUM((A1,A10:A20,A25,A28,A30, ... etc.))

 

[just1creation]

okay... here is what my formula looks like...

=SUM(B234,B228,B222,B216,B210,B204,B198,B192,B186,B180,B174,B168,B162,B156,B150,B144,B138,B132,B126,B120,B114,B108,B102,B96,B90,B84,B78,B72,B66,B60)

i need to add more cell

 

[oldchippy]

okay... here is what my formula looks like...

=SUM(B234,B228,B222,B216,B210,B204,B198,B192,B186,B180,B174,B168,B162,B156,B150,B144,B138,B132,B126,B120,B114,B108,B102,B96,B90,B84,B78,B72,B66,B60)

i need to add more cells

OK,

On the end of the formula

+SUM(B60,B45,B30......) etc after another 30 you will have to pu
another +SUM

oldchippy :

 

[just1creation]

the pattern is every 6th cell as you can see here...

=SUM(B234,B228,B222,B216,B210,B204,B198,B192,B186,B180,B174,B168,B162,B156,B150,B144,B138,B132,B126,B120,B114,B108,B102,B96,B90,B84,B78,B72,B66,B60

 

[Ragdyer]

Don't know which way you're going (up OR down), so this is just a guess at
your range.

If it's a bad guess, post back with the range you're looking to total.

=SUMPRODUCT((MOD(ROW(B60:B600),6)=0)*(B60:B600))

 

[just1creation]

OK,

On the end of the formula

+SUM(B60,B45,B30......) etc after another 30 you will have to pu
another +SUM

oldchippy

it does not work..

 

[Bob Umlas]

Like Gord indicated, use extra parens, but like this:
=SUM((A1,B2,C3,D4),(E5,F6,G7,H8),(A12,W23,R33,U22,I97),(G54,F33,F24))
To Excel, this looks like 4 arguments, not 16! You can get very creative
here, but know that each set of parens will be treated as one argument.
This has excel "think" there are 2 arguments:
=SUM(((A1,B2,C3,D4),(E5,F6,G7,H8),(A12,W23,R33,U22,I97),(G54,F33,F24)),J8)
Bob Umlas
Excel MVP

"just1creation" <[email protected]>
wrote in message
news:[email protected]...

 

[Ragdyer]

Bob,
All you need is *one* set of *double * parenthesis, as in my post!

 

[just1creation]

from B6 to B23

 

[Ragdyer]

Then just simply replace that range in my formula:

=SUMPRODUCT((MOD(ROW(B6:B234),6)=0)*(B6:B234))

 

[just1creation]

one more problem... it gives me a value error because in that same
column i have text. without the text it adds fine but with the text i
get an error...

 

[Ragdyer]

Then try this:

=SUMPRODUCT(--(MOD(ROW(B6:B234),6)=0),B6:B234)

 

[oldchippy]

from B6 to B234

Hi just1creation,

I've slept on it now this works

=SUMPRODUCT((MOD(ROW(B6:B232),2)=0)*(B6:B232))

oldchippy :

 

[oldchippy]

one more problem... it gives me a value error because in that same
column i have text. without the text it adds fine but with the text i
get an error...

Sorry didn't read this one

Now this does work

=SUM((B234,B228,B222,B216,B210,B204,B198,B192,B186,
B180,B174,B168,B162,B156,B150,B144,B138,B132,B126,
B120,B114,B108,B102,B96,B90,B84,B78,B72,B66,B60,B54,B48,B42,B36,B30,B24,B18,B12,B6))

oldchippy