Working days in a month?

[Luc]

Hi all,

I'm trying to put together a budget for a freelancer. She works on Mondays
and Wednesdays and Saturday mornings. Is it possible to create a formula
which will tell me how many days in each month the above occur.

So if there were four weeks exactly, I would want the formula to tell that
there are: 4 mondays, 4 wednesdays, and 4 saturdays, giving me 10 working
days.

Thanks for any help,

Luc

 

[Frank Kabel]

Hi
try the following:
1. Enter the starting date in cell A1
2. Enter the ending date in cell A2
3. Now use the following formula
=SUMPRODUCT(--(WEEKDAY(ROW(INDIRECT(A1 & ":" & A2)))={2,4,7}))

 

[Luc]

thanks Frank.

I've adapted that formula slightly to count number of 2,4 days and half 7
days.

works a treat!

Luc

 

[Daniel.M]

Hi Luc,

One way:

With your year in A1 '2004
and your month number in A2 ' 1 to 12, 1 for Jan, 12 for Dec

For the total:
=SUM(INT((DATE(A1,A2+1,)-WEEKDAY(DATE(A1,A2+1,)-{1;3;6})-
DATE(A1,A2,1)+8)/7)/{1;1;2})

If you want to know the number for each specific day (Mon, Wed, Sat), select 3
vertical cells and array (Ctrl-Shift-Enter) enter this formula:

=INT((DATE(A1,A2+1,)-WEEKDAY(DATE(A1,A2+1,)-{1;3;6})-
DATE(A1,A2,1)+8)/7)

Regards,

Daniel M.

 

[CLR]

Hi Luc..........
One way,
Assuming your dates are in column A, in B1 put =weekday(A1) and copy
down........

Then in D1 put
=COUNTIF(B:B,1)+COUNTIF(B:B,3)+COUNTIF(B:B,6)/2

Vaya con Dios,
Chuck, CABgx3