Hi Gary,
'---------------------
what approach would i use to use look at values in a single
filtered column and populate an array with the unique numbers?
'---------------------
Try something like:
'================>>
Public Sub Tester002()
Dim WB As Workbook
Dim SH As Worksheet
Dim Rng As Range
Dim Rng2 As Range
Dim rCell As Range
Dim myCol As Collection
Dim Arr() As Variant
Dim i As Long
Set WB = ActiveWorkbook '<<===== CHANGE
Set SH = WB.Sheets("Sheet1") '<<===== CHANGE
Set Rng = SH.AutoFilter.Range '<<===== CHANGE
If Not Rng Is Nothing Then
Set Rng2 = Rng.Columns(1) '<<===== CHANGE
End If
Set Rng2 = Rng2.Offset(1).Resize(Rng2.Rows.Count - 1)
Set Rng2 = Rng2.SpecialCells(xlCellTypeVisible)
Set myCol = New Collection
On Error Resume Next
For Each rCell In Rng2.Cells
With rCell
myCol.Add .Value, CStr(.Value)
End With
Next rCell
On Error GoTo 0
'Do something with the stored unique vales, e.g.:
ReDim Arr(1 To myCol.Count)
For i = 1 To myCol.Count
Debug.Print myCol(i)
'Optionally, load an array:
Arr(i) = myCol(1)
Next i
End Sub
'<<================
Subject to your requirements, the collection may render use of an array
superfluous.