Printing Notes Page Of Current Slide

[Guest]

I'm trying to print the notes page of a slide. I'm using the following code
from a button on that particular slide.

With ActivePresentation.PrintOptions
.RangeType = ppPrintCurrent
.NumberOfCopies = 1
.Collate = msoTrue
.OutputType = ppPrintOutputNotesPages
.PrintHiddenSlides = msoTrue
.PrintColorType = ppPrintBlackAndWhite
.FitToPage = msoFalse
.FrameSlides = msoFalse
'.ActivePrinter
End With
ActivePresentation.PrintOut

The problem is that is prints the previous slide's notes rather than the
slide with the button. Is it a matter of focus? Is there code I can use to
insure that the focus is on the page with the button before executing the
above? I want to use the button\code on several different slides.

Any help would be appreciated.

 

[Steve Rindsberg]

Actually, it's printing whatever slide you were viewing in edit mode before you
started the show. It's not obvious that this isn't the same as the slide
that's in view during a slide show, but that's the name of the game.

Use this instead (you can put the same button on each page, each pointing to
this same macro and it'll only print the current slide being viewed, by the
way)

And thanks for asking. I've added this to the PPT FAQ and sorta named it after
you ;-)

Print just the current slide from Slide Show View
http://www.rdpslides.com/pptfaq/FAQ00763.htm

Sub PrintMeAndMeOnly()

Dim lCurrentSlide as Long

' Get the SlideID of the slide currently in view
lCurrentSlide = SlideShowWindows(1).View.Slide.SlideIndex

With ActivePresentation.PrintOptions

' Print a range that includes only the current slide
.RangeType = ppPrintSlideRange
With .Ranges
.ClearAll
.Add Start:=lCurrentSlide, End:=lCurrentSlide
End With

.NumberOfCopies = 1
.Collate = msoTrue
.OutputType = ppPrintOutputNotesPages
.PrintHiddenSlides = msoTrue
.PrintColorType = ppPrintBlackAndWhite
.FitToPage = msoFalse
.FrameSlides = msoFalse
'.ActivePrinter
End With
ActivePresentation.PrintOut

End Sub

 

[Guest]

Great! Exactly what I needed. Thanks for the help and quick response.