macro that displays function from 2 columns

[FA]

I have 2 columns in my spreadsheet that contain either True or False entries.
I'm looking to create a macro that will display the True entries from either
column.
If my sheet looks like this,

A B
1 True False
2 True False
3 False False
4 False True
5 False True

Then I want the macro to display only rows 1,2,4 & 5. The colums are never
both True so I don't have to worry about that.
I'm stuck with coming up with a function that will work, any help would be
appreciated!

 

[Jacob Skaria]

Try the below macro...

Sub Macro()
Dim lngRow As Long
For lngRow = 1 To Cells(Rows.Count, "A").End(xlUp).Row
If Range("A" & lngRow) + Range("b" & lngRow) = 0 Then _
Rows(lngRow).Hidden = True
Next
End Sub

If this post helps click Yes

 

[Jacob Skaria]

If you have text values try

Sub Macro()
Dim lngRow As Long
For lngRow = 1 To Cells(Rows.Count, "A").End(xlUp).Row
If Range("A" & lngRow) = "False" And Range("b" & lngRow) = "False" Then _
Rows(lngRow).Hidden = True
Next
End Sub

If this post helps click Yes

 

[Gary''s Student]

Sub DoubleFalseHide()
n = Cells(Rows.Count, 1).End(xlUp).Row
For i = 1 To n
v1 = Cells(i, 1).Value
v2 = Cells(i, 2).Value
If v1 = True Or v1 = "True" Then
Else
If v1 = True Or v2 = "True" Then
Else
Cells(i, 1).EntireRow.Hidden = True
End If
End If
Next
End Sub


This should work whether the cells contain text or booleans.

 

[Jim Thomlinson]

Assuming you have boolean true and false inthe cells and not text true and
false then...

Public Sub HideFalse()
Dim rng As Range
Dim rngToSearch As Range

With Sheets("Sheet1") 'Specify the sheet
Set rngToSearch = .Range(.Range("A1"), .Cells(Rows.Count, "A").End(xlUp))
End With

For Each rng In rngToSearch
If Not (rng.Value Or rng.Offset(0, 1).Value) Then _
rng.EntireRow.Hidden = True
Next rng

End Sub