Formating numbers &"Text" to appear as currency &"Text" in formula

[Guest]

Hi,
There was no prior question to this issue. So I thought this would be a
challenge...

Using Windows XP with Excel 2003. The content of the cell is:
=if(A1>A2," You owe me "&(A2-A1),if(A1<A2,"I owe you "&(A1-A2),"No
outstandings"),"")

Sample of outcome is
You owe me 556677.123

Would like the outcome to be
You owe me $556,677.13

Already tried changing cell format to Currency but still appears as sample
outcome. Thank you for all responses.

PS: A hearty appreaciation if anyone sends me $556,677.13

 

[Jon Peltier]

" You owe me "&TEXT(A2-A1,"$#,##0.00")
etc.

- Jon

 

[Pete_UK]

I don't have that kind of money to give away, but I can give you my
solution to your problem - use the TEXT function, like so:

=if(A1>A2," You owe me "&TEXT(A2-A1,"$0.00"),if(A1<A2,"I owe you
"&TEXT(A1-A2,"$0.00"),"No outstandings"))

Hope this helps.

Pete

 

[David Biddulph]

=if(A1>A2," You owe me "&TEXT(A2-A1,"$#,##0.00"),if(A1<A2,"I owe you
"&TEXT(A1-A2,"$#,##0.00"),"No outstandings"),"")

If you want to do the rounding up of .123 to .13, then include
ROUNDUP(...,2)

 

[Guest]

try this

=IF(A1>A2," You owe me " &DOLLAR(A2-A1),IF(A1<A2,"I owe you
"&DOLLAR(A1-A2),"No outstandings"))

 

[Dave Peterson]

One more:

=IF(A1=A2,"No Outstandings",
IF(A1>A2,"You owe me ","I owe you ")&TEXT(ABS(A1-A2),"$#,##0.00"))

(all one cell)

 

[Guest]

Thank you to Jon, Mike, Pete, David and Dave!

To reader,
If you find their replies helpful, please vote Yes! to them. Thank you.