Fiscal Quarter Conversion

[Guest]

Is there a way to convert dates into their respective fiscal quarters. For
instance, if A2 = 10/15/07, I want A3 = Q3.

 

[Guest]

I'm doing this for a calendar quarter as opposed to a fiscal quarter. I'm
not sure of your fiscal calendar.

=IF(MONTH(A2)>=10,"Q4",IF(MONTH(A2)>=7,"Q3",IF(MONTH(A2)>=4,"Q2","Q1")))

 

[Guest]

Define your quarters:

Assume Q1 = 1/1/2007 to 3/31/2007, etc., etc.

So,
=IF(A1>10/1/2007,"Q4",IF(AND(A1>7/1/2007,A1<=9/30/2007),Q3,IF(AND(A1>4/1/2007,A1<7/1/2007),Q2,Q1)))

Dave

 

[Peo Sjoblom]

Yes it can be done, I assume your fiscal years starts on April 1st

="Q"&INDEX({4;1;2;3},INT((MONTH(A2)+2)/3))

 

[Guest]

With a date in cell A1

Try something like this:
B1: ="Q"&CEILING(MONTH(A1)/12*4,1)

Does that help?
***********
Regards,
Ron

XL2002, WinXP

 

[T. Valko]

For calendar quarters:

="Q"&CEILING(MONTH(A1)/3,1)

Biff

 

[Guest]

Ooops! I totally missed the "fiscal year" situation.
Nice catch (and good solution), Peo!

***********
Regards,
Ron

XL2002, WinXP

 

[Harlan Grove]

Yes it can be done, I assume your fiscal years starts on April 1st

="Q"&INDEX({4;1;2;3},INT((MONTH(A2)+2)/3))

More generally, if the fiscal year beginning date (text in MM/DD
format) were given by the name FYBD, the fiscal quarter would be given
by

=TEXT((DATEDIF(FYBD&"/1904",$A2,"YM")+2)/3,"\Q0")