Display multiple results based on one cell

[Cul]

I need help coming up with a formula that will display Level 1, Level 2,
Level 3, and Level 4 based on what the cell is. If the number is 475 - 490
display Level 1. If the number is 491-500 display level 2. if the number is
501-510 - Level 3. and 511-infinity display Level 4.

The result would look like this
489 Level 1
502 Level 3
477 Level 1

 

[Shane Devenshire]

Hi,

Create a table like this

475 Level 1
491 Level 2
501 Level 3
511 Level 4

say in A1:B4

In D1 enter the number you want to look up and in F1 the following formula

=VLOOKUP(D1,$A$1:$B$4,2,TRUE)

 

[Bernard Liengme]

Suppose the number is in A1
=IF(A1>510,"Level 4",IF(A1>500,"Level 3", IF(A1>490, "Level 2", IF(A1>=475,
"Level 1", "too small"))))
OR
=LOOKUP(A1,{475,491,501,511},{"Level 1","Level 2","Level 3","Level 4"})
best wishes

 

[Teethless mama]

=LOOKUP(A1,{475,491,501,511},"Level "&{1,2,3,4})

 

[Cul]

Theethless, your fomula works just like I want but I also wanted it to return
a blank cell if there was nothing in the A1 column vs the N/A that shows up.

Thanks,
Michael

 

[Teethless mama]

=IF(A1="","",LOOKUP(A1,{475,491,501,511},"Level "&{1,2,3,4}))