Sorry, I didn't read your post carefully. The code I posted plays the sound
whenever A1 is manually changed. If you want the sound to play when the cell
value is changed manually to, say, 10, then change the first part to:
Sub Worksheet_Change(ByVal Target As Range)
Dim strSoundPath As String
Dim strSoundFile As String
'Change path and file name
strSoundPath = "C:\I386\"
strSoundFile = "Chimes.WAV"
'Change cell address and value to suit
If Not Intersect(Target, Me.[A1]) Is Nothing Then
If Target.Value = 10 Then
Call sndPlaySound32(strSoundPath & strSoundFile, 0)
End If
End If
End Sub
---
If there is a formula in A1, then use:
Private Sub Worksheet_Calculate()
Dim strSoundPath As String
Dim strSoundFile As String
'Change path and file name
strSoundPath = "C:\I386\"
strSoundFile = "Chimes.WAV"
'Change cell address and value to suit
If Me.[A1].Value = 10 Then
Call sndPlaySound32(strSoundPath & strSoundFile, 0)
End If
End Sub
---
HTH
Jason
Atlanta, GA
Jason Morin said:
Let's assume A1. Right-click the worksheet tab, select View Code, and place
in the following:
Sub Worksheet_Change(ByVal Target As Range)
Dim strSoundPath As String
Dim strSoundFile As String
'Change path and file name
strSoundPath = "C:\I386\"
strSoundFile = "Chimes.WAV"
'Change cell address if not A1
If Not Intersect(Target, Me.[A1]) Is Nothing Then
Call sndPlaySound32(strSoundPath & strSoundFile, 0)
End If
End Sub
---
Now place the following in a regular module:
'Play sound -
www.cpearson.com
Public Declare Function sndPlaySound32 Lib "winmm.dll" Alias _
"sndPlaySoundA" (ByVal lpszSoundName As String, _
ByVal uFlags As Long) As Long
---
HTH
Jason
Atlanta, GA
SellUnHi said:
I would like to add an audio alert to a spreadsheet cell whenever it changes
to a specific value? Can this be done?