scubadiver said:
What does this code do and where do I find it on mvps?
Here's a copy of a posting from a few years back, don't ask me to explain
any of the code because I've not used it since and I found the whole
experience made my head hurt:
Can you use the "SendObject" action in Access VBA with Lotus Notes?
Well the short answer is yes but it isnt easy at all. I got this code from
the net which may be of help. I have actually got this code to work but it
is very flakey in terms of reliability.
*******
Lotus Notes from VB or VBA
This piece of code shows you how to mail direct from VBA into lotus
notes. Requires Lotus Notes Client 4.5.x or later is installed on your
system.
As far as I can tell the Lotus Notes objects all have to be late bound
otherwise you get errors. I have never found out the reason for this (the
only thing I can think of is there is an error in the lotus notes api). Feel
free to use this code, but if you do you it, I would appreciate a link from
your site if you have one.
Point of note. Certain versions of 4.x client handle differently. If you get
an error about object already exists, or two attachments instead of one, you
will need to comment out the line that reads MailDoc.CREATERICHTEXTITEM
("Attachment"). In later versions of notes API this task is carried out by
the previous line.
'Public Sub SendNotesMail(Subject as string, attachment as string,
'recipient as string, bodytext as string,saveit as Boolean)
'This public sub will send a mail and attachment if neccessary to the
'recipient including the body text.
'Requires that notes client is installed on the system.
Public Sub SendNotesMail(Subject As String, Attachment As String, Recipient
As String, BodyText As String, SaveIt As Boolean)
'Set up the objects required for Automation into lotus notes
Dim Maildb As Object 'The mail database
Dim UserName As String 'The current users notes name
Dim MailDbName As String 'THe current users notes mail database name
Dim MailDoc As Object 'The mail document itself
Dim AttachME As Object 'The attachment richtextfile object
Dim Session As Object 'The notes session
Dim EmbedObj As Object 'The embedded object (Attachment)
'Start a session to notes
Set Session = CreateObject("Notes.NotesSession")
'Get the sessions username and then calculate the mail file name
'You may or may not need this as for MailDBname with some systems you
'can pass an empty string
UserName = Session.UserName
MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) -
InStr(1, UserName, " "))) & ".nsf"
'Open the mail database in notes
Set Maildb = Session.GETDATABASE("", MailDbName)
If Maildb.ISOPEN = True Then
'Already open for mail
Else
Maildb.OPENMAIL
End If
'Set up the new mail document
Set MailDoc = Maildb.CREATEDOCUMENT
MailDoc.Form = "Memo"
MailDoc.sendto = Recipient
MailDoc.Subject = Subject
MailDoc.Body = BodyText
MailDoc.SAVEMESSAGEONSEND = SaveIt
'Set up the embedded object and attachment and attach it
If Attachment <> "" Then
Set AttachME = MailDoc.CREATERICHTEXTITEM("Attachment")
Set EmbedObj = AttachME.EMBEDOBJECT(1454, "", Attachment,
"Attachment")
MailDoc.CREATERICHTEXTITEM ("Attachment")
End If
'Send the document
MailDoc.PostedDate=Now() 'Gets the mail to appear in the sent items
folder
MailDoc.SEND 0, Recipient
'Clean Up
Set Maildb = Nothing
Set MailDoc = Nothing
Set AttachME = Nothing
Set Session = Nothing
Set EmbedObj = Nothing
End Sub
If you want to send a message to more than one person or copy or blind
carbon copy the following may be of use to you.
MailDoc.sendto = Recipient
MailDoc.CopyTo = ccRecipient
MailDoc.BlindCopyTo = bccRecipient
Also for multiple email addresses you just set MailDoc.sendto to an array of
variants each of which will receive the message. So
Dim recip(25) as variant
recip(0) = "emailaddress1"
recip(1) = "emailaddress2" e.t.c
maildoc.sendto = recip
Thanks must go out to
Mark Austin, Long Beach, California
assisted by the great folks at
www.deja.com &
www.notes.net
*******
I also found this which uses SendObject but i have never tried it and so
dont know how good it is.
*******
The following code snippet should send an Email via Lotus Notes from within
Access without using SendObject
Dim notesdb As Object
Dim notesdoc As Object
Dim notesrtf As Object
Dim notessession As Object
Set notessession = CreateObject("Notes.Notessession")
Set notesdb = notessession.getdatabase("", "")
Call notesdb.openmail
Rem make new mail message
Set notesdoc = notesdb.createdocument
Call notesdoc.replaceitemvalue("Sendto", strSupportEMail)
Call notesdoc.replaceitemvalue("Subject", "Problem Report")
Set notesrtf = notesdoc.createrichtextitem("body")
Call notesrtf.appendtext("Problem Report")
Call notesrtf.addnewline(2)
Rem attach Error Report doc
's = ActiveDocument.Path + "\" + ActiveDocument.Name
Call notesrtf.embedObject(1454, "", strCurrentPath, "Mail.rtf")
Rem send message
Call notesdoc.Send(False)
Set notessession = Nothing
GB located the following snippet for passing the password.
Dim MailPassword As String
Dim lnSession As NotesSession
Set lnSession = CreateObject("Lotus.NotesSession")
Call lnSession.Initialize(MailPassword)