Graham Seach, ACCESS MVP, posted a VBA function that will mimic the bolding
characteristic of older version's message box:
Public Function FMsgBox(sLine1 As String, sLine2 As String, _
sLine3 As String, Optional lButtons As VbMsgBoxStyle = vbOKOnly, _
Optional sTitle As String = vbNullString, Optional HelpFile As Variant,
_
Optional Context As Variant) As VbMsgBoxResult
'
'Description: This function creates a formatted MsgBox
' similar to that which was available in Access 97 and
' earlier versions.
'
'Inputs: sLine1: The first line of text to be displayed.
' sLine2: The second line of text to be displayed.
' sLine3: The third line of text to be displayed.
' lButtons: The buttons to be displayed (exposed
' as a vbMsgBoxStyle enum).
' Title: The (optional) MsgBox title.
' HelpFile: The (optional) help filename.
' If HelpFile is supplied, then Context
' must also be supplied.
' Context: The (optional) context or topic ID.
'
'Outputs: The standard MsgBox return value.
Dim sPrompt As String
'All three lines must exist
If Len(sLine1) > 1 And Len(sLine2) > 0 And Len(sLine3) > 0 Then
sPrompt = sLine1 & "@" & sLine2 & "@" & sLine3
If IsMissing(HelpFile) Or IsMissing(Context) Then
FMsgBox = Eval("MsgBox(""" & sPrompt & """, " _
& lButtons & ", """ & sTitle & """)")
Else
FMsgBox = Eval("MsgBox(""" & sPrompt & """, " _
& lButtons & ", """ & sTitle & """, """ _
& HelpFile & """, " & Context & ")")
End If
Else
DoCmd.Beep
MsgBox "You must supply all three lines.", _
vbOKOnly + vbExclamation, "Argument missing"
End If
End Function
Regards,
Graham R Seach
Microsoft Access MVP
Sydney, Australia
--
Ken Snell
<MS ACCESS MVP>
tina said:
AFAIK, you can't do it directly from VBA with the Msgbox() function. but you
can use the MsgBox action in a macro, see the Msgbox Action topic in Access
Help (*not* VBA Help) and read the Remarks section of the topic.
if necessary, you can call the macro from VBA with
DoCmd.RunMacro "MacroName"
hth
