Any way to export all review comments into a separate file Excel /Word ?

[aha]

Hi, I have a document which I have merged after consolidation of
various reviewers.
Is there any way to export all review comments / notes into a separate
file ? This would be helpful to track and assign to individuals.

Regards, Pavan

 

[aha]

Hi all....did a search and found the below macro ...which
works !!!.
Thanks to Lene Fredborg, who posted it in Jan 2007 in response to a
similar query.


Regards, Pavan

Maybe you can use the macro included below.
The macro creates a new document with a 4-column table which will be filled
with information about the comments found in the document that is active when
you start the macro. The following information will be inserted in the table:
Column 1: Page number where the comment is found
Column 2: The commented text (i.e. the text that was selected when the
comment was inserted)
Column 3: The comment itself
Column 4: Comment author

You may want to adjust the table layout (this could be done by the macro too).

Sub CreateCommentsDoc()
Dim oDoc As Document
Dim oNewDoc As Document
Dim oTable As Table
Dim nCount As Long
Dim n As Long

Set oDoc = ActiveDocument
nCount = ActiveDocument.Comments.Count

'Create a new document for the comments
Set oNewDoc = Documents.Add
'Insert a 4-column table for the comments
With oNewDoc
.Content = ""
Set oTable = .Tables.Add _
(Range:=Selection.Range, _
numrows:=nCount + 1, _
NumColumns:=4)
End With

With oTable.Rows(1)
.Range.Font.Bold = True
.Cells(1).Range.Text = "Page"
.Cells(2).Range.Text = "Comment scope"
.Cells(3).Range.Text = "Comment text"
.Cells(4).Range.Text = "Author"
End With

'Get info from each comment from oDoc and insert in table
For n = 1 To nCount
With oTable.Rows(n + 1)
'Page number
.Cells(1).Range.Text = _
oDoc.Comments(n).Scope.Information(wdActiveEndPageNumber)
'The text marked by the comment
.Cells(2).Range.Text = oDoc.Comments(n).Scope
'The comment itself
.Cells(3).Range.Text = oDoc.Comments(n).Range.Text
'The comment author
.Cells(4).Range.Text = oDoc.Comments(n).Author
End With
Next n

oNewDoc.Activate
MsgBox "Finished creating comments document."

Set oDoc = Nothing
Set oNewDoc = Nothing
Set oTable = Nothing

End Sub

--
Regards
Lene Fredborg
DocTools - Denmark
www.thedoctools.com
Document automation - add-ins, macros and templates for Microsoft Word