Question regarding wildcard in multi-criteria IF formula

[Malvaro]

For whatver reason the wildcard doesn't seem to be pulling alternative
spellings into the TRUE/FALSE criteria check. Column AG contains many
various companies, which then need to be sorted into two classes (N or
D).

My question is regarding the wildcard, which doesn't seem to be working
properly. If column AG contains: BestBuy, Best Buy, and Best Buy Co...
the formula is counting each of them as a FALSE statement because the
formula is only pulling the exact phrase of "Best" instead of "Best
(*everything after it)".

This is my current Excel 2003 formula:

=IF(OR(AG5="Good*",AG5="Best*",AG5="Circuit*"),"N","D")

What do I need to change so that the formula will pull in the wildcard
results of Best_Buy_, Best _Buy_, and Best__Buy_Co_ and specify them as
a TRUE statement and list "N" as the final result?

 

[Aladin Akyurek]

=IF(ISNUMBER(SEARCH("Best",AG5)),"N","D")

 

[Peo Sjoblom]

You can use COUNTIF

=COUNTIF(A1,"Best*")

will return 1 for a hit,

=COUNTIF(A1,"Best*")=1

will retrun TRUE

you can obviosuly do that for a range as well

=COUNTIF(A1:A10,"Best*")

or you can use IF plus some other functions

=IF(LEFT(A1,4)="Best",1,0)

this will find any occurrence of Best

=IF(ISENUMBER(SEARCH("Best",A1)),1,0)

 

[Dave Peterson]

One way:

=IF(SUM(COUNTIF(Ag5,{"best*","Good*","circuit*"}))>0,"N","D")