Opening files in a folder

[Daniel Bonallack]

Could someone please tell me how to open all the Excel
files in specific folder, via code?

For example, I have files A.xls, B.xls and C.xls in the
folder C:\VBA\OpenFiles\, along with several Word files.
What code would open these three files?

Thanks in advance

Daniel

 

[Kalle]

Sub dirreader()
YourPath = "c:\VBA\OpenFiles\,*.xls"
name1 = Dir(YourPath, vbDirectory)
Do While name1 <> ""
If name1 <> "." And name1 <> ".." Then
MsgBox name1
End If
name1 = Dir
Loop


End Su

 

[Ron de Bruin]

Try this one Daniel

Change the folder to yours

Sub Test()
Dim mybook As Workbook
Dim FNames As String
Dim MyPath As String
Dim SaveDriveDir As String

SaveDriveDir = CurDir
MyPath = "C:\Data"
ChDrive MyPath
ChDir MyPath
FNames = Dir("*.xls")
If Len(FNames) = 0 Then
MsgBox "No files in the Directory"
ChDrive SaveDriveDir
ChDir SaveDriveDir
Exit Sub
End If

Application.ScreenUpdating = False
Do While FNames <> ""
Set mybook = Workbooks.Open(FNames)
FNames = Dir()
Loop
ChDrive SaveDriveDir
ChDir SaveDriveDir
Application.ScreenUpdating = True
End Sub

 

[Daniel Bonallack]

Thank you for your replies (three different but equally
efficient solutions).

regards
Daniel