number to word

[Guest]

hi! i would like to present a number in word or text format, how would i do
that? like, 234 to two hundred thirty-four.

thanks.

 

[missinglinq via AccessMonster.com]

Here're the links to two ways to do this! Haven't used either one personally,
but both come from developers with good, solid reputations!

http://www.tek-tips.com/faqs.cfm?pid=181&fid=1740
http://www.tek-tips.com/viewthread.cfm?qid=925103

 

[missinglinq via AccessMonster.com]

Just for kicks I tested these routines and this is the easiest:

From the Access Object Dialog Box click on "Modules"

Click on new to make a new module

Copy then paste the following code into the new module:

'xxxxxxxxxxxxxxx Beginning of code xxxxxxxxxxxxxxxxx

Function English(ByVal N As Currency) As String

Const Thousand = 1000@
Const Million = Thousand * Thousand
Const Billion = Thousand * Million
Const Trillion = Thousand * Billion

If (N = 0@) Then English = "zero": Exit Function

Dim Buf As String: If (N < 0@) Then Buf = "negative " Else Buf = ""
Dim Frac As Currency: Frac = Abs(N - Fix(N))
If (N < 0@ Or Frac <> 0@) Then N = Abs(Fix(N))
Dim AtLeastOne As Integer: AtLeastOne = N >= 1

If (N >= Trillion) Then
Debug.Print N
Buf = Buf & EnglishDigitGroup(Int(N / Trillion)) & " trillion"
N = N - Int(N / Trillion) * Trillion
If (N >= 1@) Then Buf = Buf & " "
End If

If (N >= Billion) Then
Debug.Print N
Buf = Buf & EnglishDigitGroup(Int(N / Billion)) & " billion"
N = N - Int(N / Billion) * Billion
If (N >= 1@) Then Buf = Buf & " "
End If

If (N >= Million) Then
Debug.Print N
Buf = Buf & EnglishDigitGroup(N \ Million) & " million"
N = N Mod Million
If (N >= 1@) Then Buf = Buf & " "
End If

If (N >= Thousand) Then
Debug.Print N
Buf = Buf & EnglishDigitGroup(N \ Thousand) & " thousand"
N = N Mod Thousand
If (N >= 1@) Then Buf = Buf & " "
End If

If (N >= 1@) Then
Debug.Print N
Buf = Buf & EnglishDigitGroup(N)
End If

If (Frac = 0@) Then
Buf = Buf
ElseIf (Int(Frac * 100@) = Frac * 100@) Then
If AtLeastOne Then Buf = Buf & " and "
Buf = Buf & Format$(Frac * 100@, "00") & "/100"
Else
If AtLeastOne Then Buf = Buf & " and "
Buf = Buf & Format$(Frac * 10000@, "0000") & "/10000"
End If

English = Buf
End Function



Private Function EnglishDigitGroup(ByVal N As Integer) As String

Const Hundred = " hundred"
Const One = "one"
Const Two = "two"
Const Three = "three"
Const Four = "four"
Const Five = "five"
Const Six = "six"
Const Seven = "seven"
Const Eight = "eight"
Const Nine = "nine"
Dim Buf As String: Buf = ""
Dim Flag As Integer: Flag = False

Select Case (N \ 100)
Case 0: Buf = "": Flag = False
Case 1: Buf = One & Hundred: Flag = True
Case 2: Buf = Two & Hundred: Flag = True
Case 3: Buf = Three & Hundred: Flag = True
Case 4: Buf = Four & Hundred: Flag = True
Case 5: Buf = Five & Hundred: Flag = True
Case 6: Buf = Six & Hundred: Flag = True
Case 7: Buf = Seven & Hundred: Flag = True
Case 8: Buf = Eight & Hundred: Flag = True
Case 9: Buf = Nine & Hundred: Flag = True
End Select

If (Flag <> False) Then N = N Mod 100
If (N > 0) Then
If (Flag <> False) Then Buf = Buf & " "
Else
EnglishDigitGroup = Buf
Exit Function
End If

Select Case (N \ 10)
Case 0, 1: Flag = False
Case 2: Buf = Buf & "twenty": Flag = True
Case 3: Buf = Buf & "thirty": Flag = True
Case 4: Buf = Buf & "forty": Flag = True
Case 5: Buf = Buf & "fifty": Flag = True
Case 6: Buf = Buf & "sixty": Flag = True
Case 7: Buf = Buf & "seventy": Flag = True
Case 8: Buf = Buf & "eighty": Flag = True
Case 9: Buf = Buf & "ninety": Flag = True
End Select

If (Flag <> False) Then N = N Mod 10
If (N > 0) Then
If (Flag <> False) Then Buf = Buf & "-"
Else
EnglishDigitGroup = Buf
Exit Function
End If

Select Case (N)
Case 0:
Case 1: Buf = Buf & One
Case 2: Buf = Buf & Two
Case 3: Buf = Buf & Three
Case 4: Buf = Buf & Four
Case 5: Buf = Buf & Five
Case 6: Buf = Buf & Six
Case 7: Buf = Buf & Seven
Case 8: Buf = Buf & Eight
Case 9: Buf = Buf & Nine
Case 10: Buf = Buf & "ten"
Case 11: Buf = Buf & "eleven"
Case 12: Buf = Buf & "twelve"
Case 13: Buf = Buf & "thirteen"
Case 14: Buf = Buf & "fourteen"
Case 15: Buf = Buf & "fifteen"
Case 16: Buf = Buf & "sixteen"
Case 17: Buf = Buf & "seventeen"
Case 18: Buf = Buf & "eighteen"
Case 19: Buf = Buf & "nineteen"
End Select

EnglishDigitGroup = Buf

End Function

'xxxxxxxxxxxxxxx Ending of code xxxxxxxxxxxxxxxxx

Save the module and call it, say, NumbersToWords

Now from your form call the function using the syntax

english(YourNumericalValue)

As an example (since I don't know your skill level, sorry) here's what I did
to test it. After doing the above to create the module, I ran up a simple
form with two textboxes, TextNumbers and TextWords

Private Sub TextNumbers_Exit(Cancel As Integer)
Me.TextWords.Value = English(Me.TextNumbers.Value)
End Sub

Now on your form you can enter a number into the TextNumbers control, then
click out or <Tab> out of the textbox, and the word equivalent will appear in
the TextWords box!

I only know the author as M8KWR

Hope this helps!

--
There's ALWAYS more than one way to skin a cat!

Answers/posts based on Access 2000

Message posted via AccessMonster.com

 

[Van T. Dinh]

Even if you don't want currency, you can adapt the code from The Access Web:

http://www.mvps.org/access/modules/mdl0001.htm

 

[Nozza]

Even if you don't want currency, you can adapt the code from The Access Web:

http://www.mvps.org/access/modules/mdl0001.htm

Thanks for this.

Any chance of explaining what the @ symbol does at the end of the
statement

Const Thousand = 1000@

It is used elsewhere as well e.g.

If (N >= 1@) Then Buf = Buf & " "
and
If (N < 0@ Or Frac <> 0@) Then N = Abs(Fix(N))

Many thanks

Noz

 

[Van T. Dinh]

@ is the type declaration character for Currency. Basically, @ indicates to
VB that the preceding number is to be treated as a Currency value.