IS IT POSSIBLE IN EXCEL WITHOUT WRITING CODE.

  • Thread starter Thread starter HARSHAWARDHAN. S .SHASTRI
  • Start date Start date
H

HARSHAWARDHAN. S .SHASTRI

What i need is "FLIXER" Value.

FLIXER value means reverse digit.

i e FLIXER value of 123 will be 321 , FLIXER value of 12121212 will be

21212121 like that.

Awaiting quick response.

H S Shastri

=======================================================
 
This handles up to eight digits: I hope you can see the pattern to expand it for more....

=VALUE(LEFT(MOD(A1,10) & MOD(INT(A1/10),10) & MOD(INT(A1/100),10) & MOD(INT(A1/1000),10) &
MOD(INT(A1/10000),10) & MOD(INT(A1/100000),10) & MOD(INT(A1/1000000),10) &
MOD(INT(A1/10000000),10),LEN(A1)))

HTH,
Bernie
MS Excel MVP
 
With a value in A1, in B1 enter:

=IF(ISERROR(MID(A$1,LEN(A$1)+1-ROW(),1)),"",MID(A$1,LEN(A$1)+1-ROW(),1))
and copy down until blanks appear

In C1, enter:

=B1

In C2, enter:

=C1 & B2 and copy down. Here is an example:

qwerrty y y
t yt
r ytr
r ytrr
e ytrre
w ytrrew
q ytrrewq
 
Hello Shastri Ji..!!

Try following:
{=SUM(VALUE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))*10^(ROW(INDIRECT("1:"&LEN(A1)))-1))}
Thanks.
--
Dilip Kumar Pandey
MBA, BCA, B.Com(Hons.)
(e-mail address removed)
(e-mail address removed)
New Delhi, India
 
HARSHAWARDHAN. S .SHASTRI said:
What i need is "FLIXER" Value.

FLIXER value means reverse digit.

i e FLIXER value of 123 will be 321 , FLIXER value of 12121212 will be

21212121 like that.

Awaiting quick response.

H S Shastri

=======================================================
Click to expand...


This might work for you...

http://tinyurl.com/awmk88
 
Oh - If you can have 0 as the last digit, then you need to drop the VALUE wrapper and live with a
string.

HTH,
Bernie
MS Excel MVP
 
That fails when there are two or more final zero digits

HTH,
Bernie
MS Excel MVP
 
Dilip Pandeji,

Bahot khub.very very good.

Thanks.

H S Shastri

=========================================================
 
How about this?

=RIGHT(REPT("0",99)&SUMPRODUCT(10^(LEN(A1)+1-ROW(INDIRECT("1:"&LEN(A1)))-1),
MID(A1,LEN(A1)+1-ROW(INDIRECT("1:"&LEN(A1))),1)+0),LEN(A1))
 
Beautiful!

Bernie
MS Excel MVP


Glenn said:
How about this?

=RIGHT(REPT("0",99)&SUMPRODUCT(10^(LEN(A1)+1-ROW(INDIRECT("1:"&LEN(A1)))-1),
MID(A1,LEN(A1)+1-ROW(INDIRECT("1:"&LEN(A1))),1)+0),LEN(A1))
Click to expand...
 
Try his formula with numbers ending in one or more zeroes... those trailing
zeroes get dropped when FLIXER'ed. Here is a modification to the formula
which preserves the trailing zeroes in the reversed number....

=TEXT(SUM(VALUE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))*10^(ROW(INDIRECT("1:"&LEN(A1)))-1)),REPT("0",LEN(A1)))

This is still an array-entered formula, so commit it using Ctrl+Shift+Enter
and not just Enter by itself.

Note: This formula will only work for numbers having 15 digits or less.
 
This variation on .. formula which I posted elsewhere in this thread is
shorter and uses 2 function calls less...

=TEXT(SUM((MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))*10^(ROW(INDIRECT("1:"&LEN(A1)))-1)),REPT("0",LEN(A1)))
 
Actually, we don't need the VALUE function call in the formula...

=TEXT(SUM((MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))*10^(ROW(INDIRECT("1:"&LEN(A1)))-1)),REPT("0",LEN(A1)))
 
Sorry, I forgot to paste HARSHAWARDHAN. S .SHASTRI's name in to my
message... he was the creator of the original formula which I modified.
 
Back
Top