If - Function in Excel 2003: HELP!

[Can'tExcel]

I'm a novice to Excel 2003, I know what I want the 'if function" to do, but
I'm not able to input the data into the function window. I have a project
that I'm working on that have the following data:
one column of % values 25%, 20%, 15%, and 10% with corresponding dollar
figures in the next column $0 - $299.99; $300.00 - 499.99; $500.00 - 599.99;
$600+.
What I want to do with the if-function is that in one cell every time I put
in a salary amount than the function should chose the correct % amount. For
instance, If a salary is $350.00 than the if-function should select 20% in
one cell and then I need the next cell to perform the calculation of $350 x
20% .

Is there anybody that call help me!

 

[Tyro]

C1 = Salary Amount

You could also use an IF statement like:

=C1*(IF(C1>=600,10%,IF(C1>=500,15%,IF(C1>=300,20%,25%))))

OR

You could create tables like the following

A1 = 25%
A2 = 20%
A3 = 15%
A4 = 10%

B1 = 0
B2 = 300
B3 = 500
B4 = 600

Then use a formula like

=C1*OFFSET(A1:A4,MATCH(C1,B1:B4)-1,0,1,1)

OR

If you rearrange your table like

A1 = 0
A2 = 300
A3 = 500
A4 = 600

B1 = 25%
B2 = 20%
B3 = 15%
B4 = 10%

Then you could use:

=C1*VLOOKUP(C1,A11:B14,2)

Tyro

 

[Tyro]

Correction:

=C1*VLOOKUP(C1,A1:B4,2)

Tyro

C1 = Salary Amount

You could also use an IF statement like:

=C1*(IF(C1>=600,10%,IF(C1>=500,15%,IF(C1>=300,20%,25%))))

OR

You could create tables like the following

A1 = 25%
A2 = 20%
A3 = 15%
A4 = 10%

B1 = 0
B2 = 300
B3 = 500
B4 = 600

Then use a formula like

=C1*OFFSET(A1:A4,MATCH(C1,B1:B4)-1,0,1,1)

OR

If you rearrange your table like

A1 = 0
A2 = 300
A3 = 500
A4 = 600

B1 = 25%
B2 = 20%
B3 = 15%
B4 = 10%

Then you could use:

=C1*VLOOKUP(C1,A11:B14,2)

Tyro

 

[Tyro]

You could also use:

C1 = Salary amount

A1 = 25%
A2 = 20%
A3 = 15%
A4 = 10%

B1 = 0
B2 = 300
B3 = 500
B4 = 600

=C1*INDEX(A1:A4,MATCH(C1,B1:B4))

Tyro