If And Or

[mateo107]

I need to make the following formula and I can't get the syntax right..>
can anyone help me?

If A1 <> "" AND B1 OR C1 OR D1 or E1 <> "" THEN Put "50" in column G1

In words...
If A1 is not blank, and any number of B1 through E1 are not blank, then
put the number 50 in column g1.

Here are some sample outputs in case i couldn't describe this right:

A1 = abcsd | B1 = absdf || G1 = 50
A1 = absdf | D1 = adfsf C1 = 22 || G1 = 50
A1 = adlkaj || G1 = " " (nothing)

Get the idea?

 

[Biff]

Hi!

Try one of these:

=IF(AND(A1<>"",OR(B1<>"",C1<>"",D1<>"",E1<>"")),50,"")

This one is an array and needs to be entered using the key combo of
CTRL,SHIFT,ENTER:

=IF(AND(A1<>"",OR(B1:E1<>"")),50,"")

This one assumes that the range B1:E1 will not contain any formula blanks:

=IF(AND(A1<>"",COUNTA(B1:E1)),50,"")

Biff

 

[Pete_UK]

Try this in cell G1:

=IF(AND(A1<>"",OR(B1<>"",C1<>"",D1<>"",E1<>"")),50,"")

Hope this helps.

Pete

 

[JE McGimpsey]

One way:

=IF(AND(A1<>"",COUNTA(B1:E1)>0),50,"")

 

[daddylonglegs]

=if(len(a1)*len(b1&c1&d1&e1),50,"")