I need to know how to leave the cell blank

[Peter]

=IF(F23<=$BT$6,$BZ$6,IF(AND(F23>=$BS$7,F23<=$BT$7),$BZ$7,IF(AND(F23>=$BS$8,F23<=$BT$8),$BZ$8,IF(AND(F23>=$BS$9,F23<=$BT$9),$BZ$9,IF(AND(F23>=$BS$10,F23<=$BT$10),$BZ$10,IF(AND(F23>=$BS$11),$BZ$13,"0"))))))
This is my formula, how do I make the cell read zero if there is no
information in f23

 

[Gary''s Student]

=IF(F23="","",your_formula) to get a blank
=IF(F23="",0,your_formula) to get a zero

 

[Dave Peterson]

=if(f23="",0,yourlongformulahere)

=IF(F2="",0,
IF(F23<=$BT$6,$BZ$6,
IF(AND(F23>=$BS$7,F23<=$BT$7),$BZ$7,
IF(AND(F23>=$BS$8,F23<=$BT$8),$BZ$8,
IF(AND(F23>=$BS$9,F23<=$BT$9),$BZ$9,
IF(AND(F23>=$BS$10,F23<=$BT$10),$BZ$10,
IF(AND(F23>=$BS$11),$BZ$13,0)))))))

(I removed the double quotes around the 0, too.

 

[Bob Phillips]

=IF(F23="","",IF(F23<=$BT$6,$BZ$6,INDEX(BZ7:BZ11,MATCH(1,(F23>=BS7:BS11)*(F23<=BT7:BT11),0))))

which is an array formula, so enter with Ctrl-Shift-Enter.

--
---
HTH

Bob


(there's no email, no snail mail, but somewhere should be gmail in my addy)

 

[Peter]

Thanks it got me in the right direction and I figured it out!

 

[Peter]

Thanks it got me in the right direction and I figured it out!

 

[Peter]

Thanks it got me in the right direction and I figured it out!