formula to find "missing" data

[LEG]

Hi!
I am looking for a formula that can:
I have a list of (nearly) identical numbers in two columns. In one column
there are 100 numbers and in column 2 there are 90 numbers. Is there a
formula or macro which can find the 10 numbers which are in column 1, but not
in column 2 and list them in at third column?
I am testing two databases that should have the same data, but doesn't. I
have the 2007 version of Excel.
LEG

 

[Ron Rosenfeld]

Hi!
I am looking for a formula that can:
I have a list of (nearly) identical numbers in two columns. In one column
there are 100 numbers and in column 2 there are 90 numbers. Is there a
formula or macro which can find the 10 numbers which are in column 1, but not
in column 2 and list them in at third column?
I am testing two databases that should have the same data, but doesn't. I
have the 2007 version of Excel.
LEG

If your data is in A1:A100 & B1:B90, then this array-entered formula will list
the entries in A that are not found in B.

This is an **array** formula so must be entered with <ctrl><shift><enter>. If
you do it correctly, Excel will place braces {...} around the formula:


=IF(ROWS($1:1)>SUM(--ISNA(MATCH($A$1:$A$100,$B$1:$B$90,0))),
"",INDEX($A$1:$A$100,LARGE(ISNA(MATCH(
$A$1:$A$100,$B$1:$B$90,0))*ROW(INDIRECT("1:100")),ROWS($1:1))))

Fill down until you don't get any values returned.
--ron

 

[Max]

Another play using simple n fast non-array formulas

Assuming data in cols A and B, from row 2 down
In C2:
=IF(A2="","",IF(COUNTIF(B:B,A2),"",ROWS($1:1)))
Leave C1 blank

In D2:
=IF(ROWS($1:1)>COUNT(C:C),"",INDEX(A:A,SMALL(C:C,ROWS($1:1))+1))
Copy C22 down to the last row of data expected in col A, eg down to D1000?
Minimize/hide col C. Col D will return the list of items in col A not found
in col B, with results all neatly packed at the top
--
Max
Singapore
http://savefile.com/projects/236895
Downloads:17,700 Files:359 Subscribers:55
xdemechanik

 

[LEG]

Thanks - it worked!

 

[LEG]

Thanks - this one worked as well.

 

[Max]

Welcome ..
--
Max
Singapore
http://savefile.com/projects/236895
Downloads:17,800 Files:359 Subscribers:56
xdemechanik

 

[Ron Rosenfeld]

Thanks - it worked!

You're welcome. Glad to help. Thanks for the feedback.
--ron