Formula for average recorded blood pressure readings in 1 column .

[Guest]

I enter my blood pressure readings for the month in one column. Is there a
formula to average them? i.e.
120/80
130/76
128/77
______
126/78 is avg
Thanks, Harry

 

[JulieD]

Hi Harry

with you blood pressure readings in A2:A4 the following array formula will
give it to you (needs to be entered with control & shift & enter, not just
enter)

=AVERAGE(VALUE(LEFT(A2:A4,3)))&"/"&ROUND(AVERAGE(VALUE(RIGHT(A2:A4,2))),0)

Cheers
JulieD

 

[Guest]

Hi
it would be much easier if you could split it in two separate column (and
then using AVERAGE). But if you have to use it this way try:
Use the following array formula (entered with CTRL+SHIFT+ENTER):
=ROUND(AVERAGE(--LEFT(A1:A3,FIND("/",A1:A3)-1)),0) & "/" &
ROUND(AVERAGE(--MID(A1:A3,FIND("/",A1:A3)+1,10)),0)

 

[JulieD]

Hi

just a note, Frank's formula is more flexible than mine (i've assumed that
the top value is always 3 digits and the bottom always 2) .. so you're
better off going with his formula.

Cheers
JulieD

 

[Don Guillett]

I just tested Frank's on my program and it works really well. You may want
to also use MAX & MIN.
=ROUND(MAX(--LEFT($K$8:$K$41,FIND("/",$K$8:$K$41)-1)),0) & "/"
&ROUND(MAX(--MID($K$8:$K$41,FIND("/",$K$8:$K$41)+1,10)),0)

Be sure to ARRAY enter.

However, I have a program (free for asking OFF LIST ONLY!!!) that separates
into
Systolic Diastolic Pulse
125 67 68
126 64 73
123 70 73

and then you can see the charts I made.

 

[Guest]

Hi JulieD,

Your formula worked out great, however, my average goes out to 10 decimal
places on the upper number. How can I correct?

Thanks JimT