Find & Replace in Word Documents.

[Cheryl]

I have a folder with over 100 wordforms documents. I need to change the same
name and replace with the same name in all documents. Anyway to do them all
at once?

thanks

 

[Greg Maxey]

See:
http://gregmaxey.mvps.org/VBA_Find_And_Replace.htm
or
http://gregmaxey.mvps.org/Process_Batch_Folder.htm

 

[Brian]

Cheryl,

Try the following macro. Change the path to use line following the to your
folder path on the seventh line. When run you will be promted for the strings
to search/replace. When the first has been carried out you will be promted to
continue with all files in the folder.

Not my code, but I have used it frequently

Public Sub BatchReplaceAll()

Dim FirstLoop As Boolean
Dim myFile As String
Dim PathToUse As String
Dim myDoc As Document
Dim Response As Long

PathToUse = "C:\Test\"

'Error handler to handle error generated whenever
'the FindReplace dialog is closed

On Error Resume Next

'Close all open documents before beginning

Documents.Close SaveChanges:=wdPromptToSaveChanges

'Boolean expression to test whether first loop
'This is used so that the FindReplace dialog will
'only be displayed for the first document

FirstLoop = True

'Set the directory and type of file to batch process

myFile = Dir$(PathToUse & "*.doc")

While myFile <> ""

'Open document
Set myDoc = Documents.Open(PathToUse & myFile)

If FirstLoop Then

'Display dialog on first loop only

Dialogs(wdDialogEditReplace).Show

FirstLoop = False

Response = MsgBox("Do you want to process " & _
"the rest of the files in this folder", vbYesNo)
If Response = vbNo Then Exit Sub

Else

'On subsequent loops (files), a ReplaceAll is
'executed with the original settings and without
'displaying the dialog box again

With Dialogs(wdDialogEditReplace)
.ReplaceAll = 1
.Execute
End With

End If

'Close the modified document after saving changes

myDoc.Close SaveChanges:=wdSaveChanges

'Next file in folder

myFile = Dir$()

Wend

End Sub

Hope it helps,