David
Now I didn't think you could do that! When I have more time I might have
a play.
Thanks for the post.
--
Regards.
Gerry
~~~~~~~~~~~~~~~~~~~~~~~~
FCA
Stourport, Worcs, England
Enquire, plan and execute.
~~~~~~~~~~~~~~~~~~~~~~~~
"David Candy" <.> wrote in message
XL2000: How to Convert a Numeric Value into English Words
Q213360
--------------------------------------------------------------------------------
The information in this article applies to:
a.. Microsoft Excel 2000
--------------------------------------------------------------------------------
SUMMARY
This article contains sample Microsoft Visual Basic for Applications
functions that you can use to convert a numeric value in a Microsoft
Excel worksheet cell into its equivalent in English words.
MORE INFORMATION
Microsoft provides programming examples for illustration only, without
warranty either expressed or implied, including, but not limited to, the
implied warranties of merchantability and/or fitness for a particular
purpose. This article assumes that you are familiar with the programming
language being demonstrated and the tools used to create and debug
procedures. Microsoft support professionals can help explain the
functionality of a particular procedure, but they will not modify these
examples to provide added functionality or construct procedures to meet
your specific needs. If you have limited programming experience, you may
want to contact a Microsoft Certified Partner or the Microsoft fee-based
consulting line at (800) 936-5200. For more information about Microsoft
Certified Partners, please see the following page on the World Wide Web:
http://www.microsoft.com/partner/referral/
For more information about the support options available from Microsoft,
please see the following page on the World Wide Web:
http://support.microsoft.com/directory/overview.asp
How to Create the Sample Function Called SpellNumber
1.. Start Microsoft Excel.
2.. Press ALT+F11 to start the Visual Basic Editor.
3.. On the Insert menu, click Module.
4.. Type the following code into the module sheet.
Option Explicit
'Main Function
Function SpellNumber(ByVal MyNumber)
Dim Dollars, Cents, Temp
Dim DecimalPlace, Count
ReDim Place(9) As String
Place(2) = " Thousand "
Place(3) = " Million "
Place(4) = " Billion "
Place(5) = " Trillion "
' String representation of amount.
MyNumber = Trim(Str(MyNumber))
' Position of decimal place 0 if none.
DecimalPlace = InStr(MyNumber, ".")
' Convert cents and set MyNumber to dollar amount.
If DecimalPlace > 0 Then
Cents = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
"00", 2))
MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
End If
Count = 1
Do While MyNumber <> ""
Temp = GetHundreds(Right(MyNumber, 3))
If Temp <> "" Then Dollars = Temp & Place(Count) & Dollars
If Len(MyNumber) > 3 Then
MyNumber = Left(MyNumber, Len(MyNumber) - 3)
Else
MyNumber = ""
End If
Count = Count + 1
Loop
Select Case Dollars
Case ""
Dollars = "No Dollars"
Case "One"
Dollars = "One Dollar"
Case Else
Dollars = Dollars & " Dollars"
End Select
Select Case Cents
Case ""
Cents = " and No Cents"
Case "One"
Cents = " and One Cent"
Case Else
Cents = " and " & Cents & " Cents"
End Select
SpellNumber = Dollars & Cents
End Function
' Converts a number from 100-999 into text
Function GetHundreds(ByVal MyNumber)
Dim Result As String
If Val(MyNumber) = 0 Then Exit Function
MyNumber = Right("000" & MyNumber, 3)
' Convert the hundreds place.
If Mid(MyNumber, 1, 1) <> "0" Then
Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
End If
' Convert the tens and ones place.
If Mid(MyNumber, 2, 1) <> "0" Then
Result = Result & GetTens(Mid(MyNumber, 2))
Else
Result = Result & GetDigit(Mid(MyNumber, 3))
End If
GetHundreds = Result
End Function
' Converts a number from 10 to 99 into text.
Function GetTens(TensText)
Dim Result As String
Result = "" ' Null out the temporary function value.
If Val(Left(TensText, 1)) = 1 Then ' If value between 10-19...
Select Case Val(TensText)
Case 10: Result = "Ten"
Case 11: Result = "Eleven"
Case 12: Result = "Twelve"
Case 13: Result = "Thirteen"
Case 14: Result = "Fourteen"
Case 15: Result = "Fifteen"
Case 16: Result = "Sixteen"
Case 17: Result = "Seventeen"
Case 18: Result = "Eighteen"
Case 19: Result = "Nineteen"
Case Else
End Select
Else ' If value between 20-99...
Select Case Val(Left(TensText, 1))
Case 2: Result = "Twenty "
Case 3: Result = "Thirty "
Case 4: Result = "Forty "
Case 5: Result = "Fifty "
Case 6: Result = "Sixty "
Case 7: Result = "Seventy "
Case 8: Result = "Eighty "
Case 9: Result = "Ninety "
Case Else
End Select
Result = Result & GetDigit _
(Right(TensText, 1)) ' Retrieve ones place.
End If
GetTens = Result
End Function
' Converts a number from 1 to 9 into text.
Function GetDigit(Digit)
Select Case Val(Digit)
Case 1: GetDigit = "One"
Case 2: GetDigit = "Two"
Case 3: GetDigit = "Three"
Case 4: GetDigit = "Four"
Case 5: GetDigit = "Five"
Case 6: GetDigit = "Six"
Case 7: GetDigit = "Seven"
Case 8: GetDigit = "Eight"
Case 9: GetDigit = "Nine"
Case Else: GetDigit = ""
End Select
End Function How to Use the SpellNumber Sample Function
To use the sample functions to change a number to written text, use one
of the methods demonstrated in the following examples:
Method 1: Direct Entry
You can change 32.50 into "Thirty Two Dollars and Fifty Cents" by
entering the following formula into a cell:
=SpellNumber(32.50)
Method 2: Cell Reference
You can refer to other cells in the workbook. For example, enter the
number 32.50 into cell A1, and type the following formula into another
cell:
=SpellNumber(A1)
Method 3: Paste Function
You can use Paste Function to enter a custom function into a worksheet.
To use Paste Function, follow these steps:
1.. Select the cell you want.
2.. Click Paste Function on the Standard toolbar.
3.. Under Function category, click User Defined.
4.. Under Function name, click SpellNumber, and then click OK.
5.. Enter the number or cell reference you want and then click OK.
6.. Click Finish.
Additional query words:
Keywords : kbprogramming kbdta kbdtacode KbVBA kbofficeprog
Issue type : kbhowto
Technology : kbExcelSearch kbExcel2000 kbExcel2000Search
Last Reviewed: December 31, 2000
© 2001 Microsoft Corporation. All rights reserved. Terms of Use.
