Create A GUID

  • Thread starter Thread starter Derek Hart
  • Start date Start date
D

Derek Hart

I wish to create a GUID in a cell. I could put it on a macro button on the
toolbar. Does Excel have anything built in to do this, or do I need VBA
code. I would appreciate a sample.

Derek
 
Private Declare Function CoCreateGuid Lib "ole32" (Id As Any) As Long

Function CreateGUID() As String

Dim btID(0 To 15) As Byte
Dim i As Long

If CoCreateGuid(btID(0)) = 0 Then
For i = 0 To 15
CreateGUID = CreateGUID + IIf(btID(i) < 16, "0", "") + Hex$(btID(i))
Next i
CreateGUID = Left$(CreateGUID, 8) & "-" & _
Mid$(CreateGUID, 9, 4) & "-" & _
Mid$(CreateGUID, 13, 4) & "-" & _
Mid$(CreateGUID, 17, 4) & "-" & _
Right$(CreateGUID, 12)
Else
MsgBox "Error while creating GUID!"
End If

End Function


Sub test()

Cells(1) = CreateGUID()

End Sub



RBS
 
Here is an option.

________________________

Sub GenerateGUID()
Dim strGUID As String
Set TypeLib = CreateObject("Scriptlet.TypeLib")
strGUID = Left(TypeLib.GUID, 38)
Cells(1, 1).Value = strGUID
Set TypeLib = Nothing
End Sub

_________________________

Steve Yandl
 
I see helpful geniuses often refer to windows libs in the forums, where do I
find documentation on these libs, like how did you know ole32 had the guid
feature? Thx
 
Back
Top