cell + 6 months

  • Thread starter Thread starter Albert0
  • Start date Start date
A

Albert0

I have a cell within a date in the adiacent cell i want
to set the date of the cell + 6 months and so on.
How can i do that ?

Thanks

Alberto
 
Hi Alberto

=DATE(YEAR(A1),MONTH(A1)+6,DAY(A1))
(minor warning: august 31th + 6 months is after september 1st + 6 months :-)
 
Hi
as addition to Harald use
=DATE(YEAR(A1),MONTH(A1)+6,MIN(DAY(A1),DAY(DATE(YEAR(A1),MONTH(A1)+7,0)
)))
to solve the august 31th problem
Frank
 
Hi!

A general formula for adding (or subtracting) months that allows
copying across or down is:

=DATE(YEAR(A1),MONTH(A1)+AddMons,MIN(DAY($A$1),DAY(DATE(YEAR(A1),MONTH
(A1)+AddMons+1,0))))

Making the absolute reference to $A$1 ensures that the formula uses
the date in A1 if it exists AddMons ahead or the last date if it
doesn't. If you use a relative reference when copying down or across,
you can get some unusual series of dates.

An alternative that does the same by Peter Dorigo:


=MIN(DATE(YEAR(A1),MONTH(A1)+ AddMons +{1,0},DAY($A$1)*{0,1}))


--
Regards
Norman Harker MVP (Excel)
Sydney, Australia
(e-mail address removed)
Excel and Word Function Lists (Classifications, Syntax and Arguments)
available free to good homes.
 
I have a cell within a date in the adiacent cell i want
to set the date of the cell + 6 months and so on.
How can i do that ?
Click to expand...

Maybe I misunderstand the question, but doesn't
=EDATE(A1,6)
do what you want?
 
Back
Top