Adding if error to a formula

  • Thread starter Thread starter Jim
  • Start date Start date
J

Jim

Hello, I'm currently using this formula, which works perfectly :
=INDEX(Calls_Received_All!D:D,MATCH(1,(Calls_Received_All!B1:B10000=D2)*(Calls_Received_All!C1:C10000=D1),0))

I know to enter ctrl-shift-enter. However if I have not entered data yet
for one of the fields the formula is referring to I get: #N/A.

I would like the cell to be blank if the reference cells are blank.

Thank you
 
Yep.

But the error could be caused by not finding a match--not because you haven't
entered the data.

=IF(COUNTA(D1:D2)<2,"not enough data",
IF(ISNA(MATCH(1,(Calls_Received_All!B1:B10000=D2)
*(Calls_Received_All!C1:C10000=D1),0)),"no match",
INDEX(Calls_Received_All!D:D,
MATCH(1,(Calls_Received_All!B1:B10000=D2)
*(Calls_Received_All!C1:C10000=D1),0))))

Still an array formula.

When you get it working, change both those strings to "" (if you want).
 
That was perfect - thanks

Dave Peterson said:
Yep.

But the error could be caused by not finding a match--not because you haven't
entered the data.

=IF(COUNTA(D1:D2)<2,"not enough data",
IF(ISNA(MATCH(1,(Calls_Received_All!B1:B10000=D2)
*(Calls_Received_All!C1:C10000=D1),0)),"no match",
INDEX(Calls_Received_All!D:D,
MATCH(1,(Calls_Received_All!B1:B10000=D2)
*(Calls_Received_All!C1:C10000=D1),0))))

Still an array formula.

When you get it working, change both those strings to "" (if you want).
Click to expand...
 
Back
Top