lookup 2 columns, return value from third

[slezgus]

I have two tables of pretty much the same format. Column A shows a name that
may or may not be repeated a few times, while column B shows one of four
values (say, 1, 2, 3, 4). I need a formula that will return the result of
the third column, if it matches Column A and Column B.

 

[Dave Peterson]

Saved from a previous post:

If you want exact matches for just two columns (and return a value from a
third), you could use:

=index(othersheet!$c$1:$c$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100),0))

(all in one cell)

This is an array formula. Hit ctrl-shift-enter instead of enter. If you do it
correctly, excel will wrap curly brackets {} around your formula. (don't type
them yourself.)

Adjust the range to match--but you can only use the whole column in xl2007.

This returns the value in othersheet column C when column A and B (of
othersheet) match A2 and B2 of the sheet with the formula.

And you can add more conditions by just adding more stuff to that product
portion of the formula:

=index(othersheet!$d$1:$d$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100)
*(c2=othersheet!$c$1:$c$100),0))

 

[Max]

Something like this in say D1, array-entered*:
=INDEX(C2:C10,MATCH(1,(A2:A10="Name1")*(B2:B10=3),0))
Press CTRL+SHIFT+ENTER to confirm the formula