Hi,

I need to create a 'tool' that counts the number of times a particular
country appears in a list. The countries are never the same, and the
number of entries is never the same, so i need to be able to generate
a list of the coutries that appear, and then count the frequency of
which they appear.

Sorry if this is the wrong forum to post this question. I have tried
working on some basic formulas but have come to a standstill.

Thanks in advance for your help.

Gavin

Assuming the data is in column A.

B1: = A1
B2: =IF(ISERROR(MATCH(0,COUNTIF(B$1:B1,$A$1:$A$20&""),0)),"",
INDEX(IF(ISBLANK($A$1:$A$20),"",$A$1:$A$20),MATCH(0,COUNTIF(B$1:B1,$A$1:$A$20&""),0)))

B2 is an array formula, it should be committed with Ctrl-Shift-Enter, not
just Enter.
Excel will automatically enclose the formula in braces (curly brackets), do
not try to do this manually.
When editing the formula, it must again be array-entered.

C1: =IF(B1="","",COUNTIF(A:A,B1))

copy B2 and C1 down.

--
HTH

Bob

(there's no email, no snail mail, but somewhere should be gmail in my addy)

"Gavin" <(E-Mail Removed)> wrote in message
news:(E-Mail Removed)...
> Hi,
>
> I need to create a 'tool' that counts the number of times a particular
> country appears in a list. The countries are never the same, and the
> number of entries is never the same, so i need to be able to generate
> a list of the coutries that appear, and then count the frequency of
> which they appear.
>
> Sorry if this is the wrong forum to post this question. I have tried
> working on some basic formulas but have come to a standstill.
>
> Thanks in advance for your help.
>
> Gavin
>