Hi Dan
Test this one for me
Sub Basic_Example_1_Test()
Dim MyPath As String, FilesInPath As String
Dim MyFiles() As String
Dim Fnum As Long
Dim mybook As Workbook, BaseWks As Worksheet
Dim sourceRange As Range, destrange As Range
Dim rnum As Long, CalcMode As Long
Dim sh As Worksheet, I As Integer, cell As Range
'Fill in the path\folder where the files are
MyPath = "L:\My Documents\00-MASTERS"
'Add a slash at the end if the user forget it
If Right(MyPath, 1) <> "\" Then
MyPath = MyPath & "\"
End If
'If there are no Excel files in the folder exit the sub
FilesInPath = Dir(MyPath & "*.xl*")
If FilesInPath = "" Then
MsgBox "No files found"
Exit Sub
End If
'Fill the array(myFiles)with the list of Excel files in the folder
Fnum = 0
Do While FilesInPath <> ""
Fnum = Fnum + 1
ReDim Preserve MyFiles(1 To Fnum)
MyFiles(Fnum) = FilesInPath
FilesInPath = Dir()
Loop
'Change ScreenUpdating, Calculation and EnableEvents
With Application
CalcMode = .Calculation
.Calculation = xlCalculationManual
.ScreenUpdating = False
.EnableEvents = False
End With
'Add a new workbook with one sheet
Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
rnum = 1
'Loop through all files in the array(myFiles)
If Fnum > 0 Then
For Fnum = LBound(MyFiles) To UBound(MyFiles)
Set mybook = Nothing
On Error Resume Next
Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
On Error GoTo 0
If Not mybook Is Nothing Then
For Each sh In mybook.Worksheets
On Error Resume Next
With sh
Set sourceRange = .Range("A1,A3,F9,I38,I44")
End With
If Err.Number > 0 Then
Err.Clear
Set sourceRange = Nothing
End If
On Error GoTo 0
If Not sourceRange Is Nothing Then
I = 3
'Copy the file name in column A
BaseWks.Cells(rnum, "A").Value = MyFiles(Fnum)
BaseWks.Cells(rnum, "B").Value = sh.Name
For Each cell In sourceRange.Areas
BaseWks.Cells(rnum, I).Value = cell.Value
I = I + 1
Next cell
rnum = rnum + 1
End If
Next sh
mybook.Close savechanges:=False
End If
Next Fnum
BaseWks.Columns.AutoFit
End If
'Restore ScreenUpdating, Calculation and EnableEvents
With Application
.ScreenUpdating = True
.EnableEvents = True
.Calculation = CalcMode
End With
End Sub
--
Regards Ron de Bruin
http://www.rondebruin.nl/tips.htm
"dan dungan" <(E-Mail Removed)> wrote in message news:(E-Mail Removed)...
> Hi Ron,
>
> It would also be useful if I could capture the worksheet name for each
> row.
>
> Thanks,
>
> Dan
>
> On Nov 13, 2:31 pm, "Ron de Bruin" <rondebr...@kabelfoon.nl> wrote:
>> Hi Dan
>>
>> I see if I have time tomorrow to make a example for you.
>>
>> To be sure you want the cells from each sheet that is in each workbook
>> Am I correct ?
>>
>> Bed time now for me
>>
>
>
>
Similar Threads
