Sub PrettyPie()
Dim n As Long
Dim arr
Dim cht As Chart
Dim sr As Series
Dim pt As Point
' fill this array with at least as many colorindex's
' as any potential qty of points
arr = Array(55, 47, 11, 5, 49, 14, 51, 10, _
52, 12)
' ensure a chart is active
Set cht = ActiveChart
If cht Is Nothing Then
MsgBox "Select a pie chart to colour"
Exit Sub
End If
Set sr = cht.SeriesCollection(1)
For Each pt In sr.Points
pt.Interior.ColorIndex = arr(n)
If n = UBound(arr) Then
n = 0
Else
n = n + 1
End If
Next
End Sub
Consider also customizing the chart colours in the bottom two rows of the
extended palette, these are the default or automatic colours that are
applied.
Regards,
Peter T
"ML" <(E-Mail Removed)> wrote in message
news:41AFF236-6D5B-47B2-BFEC-(E-Mail Removed)...
> Hi guys,
>
> I am trying to create a macro to re-colour a selection of pie charts with
> standard colours. They all have a different number of points but I want
> the
> same colour sequence for each chart.
> For example:
> ActiveChart.SeriesCollection(1).Points(1).Interior.ColorIndex = 55
> ActiveChart.SeriesCollection(1).Points(2).Interior.ColorIndex = 47 etc...
> However, I don't know how to do it for the variable number of points.
>
> Any suggestions?
>
> Thanks.
>
|
Similar Threads
