Can anyone help with a formula/macro to check if a cell contains all numeric
characters only? in which only "," can be allowed and not even a space.

Try the below....returns TRUE if a number...

=ISNUMBER(--SUBSTITUTE(A1,",",))

--
Jacob (MVP - Excel)


"Kash" wrote:

> Can anyone help with a formula/macro to check if a cell contains all numeric
> characters only? in which only "," can be allowed and not even a space.

If the cells actually contain a comma they will be NON numeric no matter how
numbers are in it.


--
Regards
Dave Hawley
www.ozgrid.com



"Kash" <(E-Mail Removed)> wrote in message
news:54C5803F-E4C8-4FB4-9F4E-(E-Mail Removed)...
> Can anyone help with a formula/macro to check if a cell contains all
> numeric
> characters only? in which only "," can be allowed and not even a space.

I guess the OP lives in a country that uses the comma as decimal sign.
Because ISNUMERIC is localized it will happyly accept a comma in
such a locale but will return false if there is a point!

Helmut.

"ozgrid.com" <(E-Mail Removed)> schrieb im Newsbeitrag
news:uLff%23xK%(E-Mail Removed)...
> If the cells actually contain a comma they will be NON numeric no matter how
> numbers are in it.
>
> --
> Regards
> Dave Hawley
> www.ozgrid.com
>
>
> "Kash" <(E-Mail Removed)> wrote in message
> news:54C5803F-E4C8-4FB4-9F4E-(E-Mail Removed)...
>> Can anyone help with a formula/macro to check if a cell contains all numeric
>> characters only? in which only "," can be allowed and not even a space.
>

"Kash" <(E-Mail Removed)> schrieb im Newsbeitrag
news:54C5803F-E4C8-4FB4-9F4E-(E-Mail Removed)...
> Can anyone help with a formula/macro to check if a cell contains all numeric
> characters only? in which only "," can be allowed and not even a space.


Hmm,

I assume your localized version of Excel is using the comma as
decimal sign, right?
Then how about negative values?

BTW, the suggested IsNumeric will accept values like
"543E12" or "120D4" as numeric if used in VBA.
The Excel spreadsheet function with the same name however
will return False in the second case (tested with Excel 97).
Excel will recognize it as a number if I enter 123E4 into a
cell and automatically convert it to 1.23E+06 (=1230000)
using scientific notation. 123D4 however is treated as
text and not recognized as scientific notation.

Helmut.

> BTW, the suggested IsNumeric will accept values like
> "543E12" or "120D4" as numeric if used in VBA.

Unfortunately, the IsNumeric function in VBA will accept a lot more than
that as numeric!

From a previous post of mine...

I usually try and steer people away from using IsNumeric to "proof"
supposedly numeric text. Consider this (also see note below):

ReturnValue = IsNumeric("($1,23,,3.4,,,5,,E67$)")

Most people would not expect THAT to return True. IsNumeric has some "flaws"
in what it considers a proper number and what most programmers are looking
for.

Several years ago, I had a short tip published by Pinnacle Publishing in
their Visual Basic Developer magazine that covered some of these flaws.
Originally, the tip was free to view but is now viewable only by
subscribers.. Basically, it said that IsNumeric returned True for things
like -- currency symbols being located in front or in back of the number as
shown in my example (also applies to plus, minus and blanks too); numbers
surrounded by parentheses as shown in my example (some people use these to
mark negative numbers); numbers containing any number of commas before a
decimal point as shown in my example; numbers in scientific notation (a
number followed by an upper or lower case "D" or "E", followed by a number
equal to or less than 305 -- the maximum power of 10 in VB); and
Octal/Hexadecimal numbers (&H for Hexadecimal, &O or just & in front of the
number for Octal).

NOTE:
======
In the above example and in the referenced tip, I refer to $ signs and
commas and dots -- these were meant to refer to your currency, thousands
separator and decimal point symbols as defined in your local settings --
substitute your local regional symbols for these if appropriate.

As for your question about checking numbers, here are two functions that I
have posted in the past for similar questions..... one is for digits only
and the other is for "regular" numbers:

Function IsDigitsOnly(Value As String) As Boolean
IsDigitsOnly = Len(Value) > 0 And _
Not Value Like "*[!0-9]*"
End Function

Function IsNumber(ByVal Value As String) As Boolean
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9.]*" And _
Not Value Like "*.*.*" And _
Len(Value) > 0 And Value <> "."
End Function

Here are revisions to the above functions that deal with the local settings
for decimal points (and thousand's separators) that are different than used
in the US (this code works in the US too, of course).

Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
Not Value Like "*" & DP & "*" & DP & "*" And _
Len(Value) > 0 And Value <> DP
End Function

I'm not as concerned by the rejection of entries that include one or more
thousand's separators, but we can handle this if we don't insist on the
thousand's separator being located in the correct positions (in other words,
we'll allow the user to include them for their own purposes... we'll just
tolerate their presence).

Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
Dim TS As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Get local setting for thousand's separator
' and eliminate them. Remove the next two lines
' if you don't want your users being able to
' type in the thousands separator at all.
TS = Mid$(Format$(1000, "#,###"), 2, 1)
Value = Replace$(Value, TS, "")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
Not Value Like "*" & DP & "*" & DP & "*" And _
Len(Value) > 0 And Value <> DP
End Function

--
Rick (MVP - Excel)